¿Cómo pasar el cuadro de diálogo de visualización de AppleScripts a Growl o growlnotify?

Question

Tengo este AppleScript simple que toma el texto en el portapapeles y genera la cantidad de palabras y caracteres utilizados.

Lo que intento hacer es pasar el "diálogo de visualización" a Growl o growlnotify. Sé cómo usar growlnotify en el shell; es excelente y altamente personalizable (pegue una nota, asigne un ícono de aplicación o una imagen, etc.), pero el punto es: no sé cómo hacerlo en AppleScript. Busqué en Google un poco pero ya pasó el tiempo y decidí publicar mi pregunta aquí.

Entonces, aquí está el guión:

set myCount to count (the clipboard)
set myWords to count words of (the clipboard)
set myParas to count paragraphs of (the clipboard)

display dialog "Characters: " & myCount & "
Words: " & myWords & "
Paragraphs: " & myParas

Gracias.

Answer 1

haydocumentaciónpara ello pongo un ejemploen esta respuesta.

Lo siguiente funciona con Growl 1.3.3 en OS X Lion:

tell application "Growl"
    set the allNotificationsList to {"Word Count"}
    set the enabledNotificationsList to {"Word Count"}

    register as application "Word Counter" all notifications allNotificationsList default notifications enabledNotificationsList icon of application "Script Editor"

    set myCount to count (the clipboard)
    set myWords to count words of (the clipboard)
    set myParas to count paragraphs of (the clipboard)
    --       Send a Notification...
    notify with name "Word Count" title "Word Counter" description (myCount as text) & " " & (myWords as text) & " " & (myParas as text) application name "Word Counter"
end tell

Answer 2

set input to the clipboard as text
set output to (number of characters of input & " characters
" & number of words of input & " words
" & number of paragraphs of input & " paragraphs") as text
do shell script "/usr/local/bin/growlnotify " & quoted form of output
-- brew install growlnotify