☰

¿Cómo cambio el idioma de todas las diapositivas de Powerpoint a la vez?

tag-icon • tag-icon windows microsoft-office microsoft-powerpoint microsoft-powerpoint-2010
¿Cómo cambio el idioma de todas las diapositivas de Powerpoint a la vez?

Quiero cambiar el idioma de revisión de todas mis diapositivas en un Powerpoint. Intenté configurar el idioma a través del menú Preferencias de idioma, sin embargo, esto solo lo cambia para nuevos powerpoints.

Respuesta1

Para cambiar el idioma delcompletoPowerPoint fácilmente, abre elVistapestaña y seleccione laDescribirvista.

Ahora presiona

  • Ctrl+ Apara seleccionar todo.
  • Herramientas→Idioma→ Elija su idioma para configurar.

Del mismo modo, mientras tienes todo seleccionado, puedes cambiar otras cosas como fuentes, colores, etc. Aunque, por supuesto, en muchos casos esto se hace mejor cambiando el patrón de diapositivas, una presentación que ha tenido muchos editores puede tener muchos formatos "duros" establecidos que se desvía del maestro subyacente y necesita restablecerse para que sea consistente. También puede restablecer diapositivas individuales al estilo maestro, pero esto puede provocar que los marcadores de posición también se muevan, lo que puede no ser deseable en algunas situaciones.

PowerPoint 2013

  • Vista→Describir→ seleccione todas las diapositivas (en un menú de la izquierda) mediante Ctrl+ A.
  • Revisar→Idioma→Establecer idioma de revisión...→ Elija su idioma para configurar.

En cuanto a mí - PowerPointReanudarera necesario. Probablemente porque yo también cambié.Idioma de edición:

  • Revisar→Idioma→Establecer idioma de revisión...→Preferencias de idioma→Elija idiomas de edición.

Respuesta2

Usandopower point 2010Abrí el menú Esquema -

pestaña de esquema

Seleccioné todo el texto (Ctrl+A), abrí el menú de idioma y configuré mi idioma de revisión.

opción de idioma

¡Y funcionó!

El menú de idioma se encuentra en la pestaña de la cinta Revisar (después de la pestaña Presentación de diapositivas y no es visible en la captura de pantalla).

Respuesta3

he mejoradoLa respuesta de Íñigo.para proporcionar una versión recursiva que cambia todos los elementos al idioma deseado.

Esta versión investigará recursivamente cada forma que sea un tipo de grupo. Algunos experimentos sugieren que msoGroupy msoSmartArtson los tipos de grupo; siéntase libre de agregarlos a esa lista si encuentra otros tipos de formas que puedan contener objetos de texto.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Respuesta4

Según las respuestas de Inigo, Duncan, Maria y DomDev, esto funciona para formas, tablas, grupos, SmartArt, ahora y en el futuro:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

información relacionada