☰

Vlookup con valores duplicados a través de AWK

tag-icon • tag-icon awk
Vlookup con valores duplicados a través de AWK

Es necesario realizar una búsqueda visual desde dos archivos diferentes que tengan entradas duplicadas:

Archivo 1

abc     10
xyz     20
bhy     30
hgf     40

Archivo 2

a   abc     
b   xyz     
c   bhy     
d   abc     
e   abc     
f   xyz

Salida requerida:

abc     10  a,d,e
xyz     20  b,f
bhy     30  c
hgf     40  Not_Available

Respuesta1

Awksolución:

awk 'NR == FNR { a[$1] = $2 OFS; next }
     $2 in a { a[$2] = a[$2] (a[$2] ~ /\t$/? "" : ",") $1 }
     END { for (i in a) print i, a[i] }' OFS='\t' file1 file2

La salida:

bhy 30  c
abc 10  a,d,e
xyz 20  b,f

Para su última condición utilice la siguiente modificación:

awk 'NR == FNR { a[$1] = $2 OFS; next }
     $2 in a { a[$2] = a[$2] (a[$2] ~ /\t$/? "" : ",") $1 }
     END {
         for (i in a) print i, a[i] (a[i] ~ /\t$/? "Not_Available" : "")
     }' OFS='\t' file1 file2

Respuesta2

con awk

awk -v OFS='\t' '
    NR == FNR {val[$1]=$2; next} 
    {items[$2] = items[$2] " " $1}
    END {
        for (a in val) {
            sub(/^ /, "", items[a])
            gsub(/ /, ",", items[a]) 
            print a, val[a], items[a]
        }
    }
' file1 file2

bhy     30      c
abc     10      a,d,e
xyz     20      b,f

Si quieres que esté ordenado, canalízalo hacia| sort -k2,2n

Sólo por diversión, un poco complicado de Perl.

perl -lae '
    if ($. == ++$nr) { $val{$F[0]} = $F[1] }
    else             { push @{$items{$F[1]}}, $F[0] }
  } continue {
    close ARGV if eof
  } END { 
    printf "%s\t%s\t%s\n", $_, $val{$_}, join(",", @{$items{$_}}) for keys %items 
' file1 file2

información relacionada