☰

Transferir solo tablas de Microsoft Word a Excel mediante automatización

tag-icon • tag-icon microsoft-excel microsoft-word automated-builds
Transferir solo tablas de Microsoft Word a Excel mediante automatización

¿Existe alguna manera de automatizar la copia de información de tablas de Microsoft Word a tablas de Microsoft Excel?

Respuesta1

Sí, esto es muy posible. como yodemostradoAyer mismo podía utilizar la automatización de Word y Excel a través de VBScript para hacer cualquier cosa que admita VBA. Pruebe el siguiente script VBS:

Option Explicit

Dim objWord, objDoc, objExcel, objSheet, tbl, srcRow, dstRow, col, cell

Set objWord = CreateObject("Word.Application")
objWord.Visible = False
objWord.DisplayAlerts = False
objWord.Documents.Open "C:\MyDoc.docx", False, True ' path, confirmconversions, readonly
Set objDoc = objWord.ActiveDocument

Set objExcel = CreateObject("Excel.Application")
objExcel.Visible = False
objExcel.DisplayAlerts = False
objExcel.Workbooks.Add
Set objSheet = objExcel.ActiveSheet

dstRow = 0
For Each tbl In objDoc.Tables
    For srcRow = 1 To tbl.Rows.Count
        col = 0
        For Each cell In tbl.Rows(srcRow).Cells
            col = col + 1
            objSheet.Cells(dstRow+srcRow, col).Value = Left(cell.Range.Text, Len(cell.Range.Text)-1)
        Next
    Next
    dstRow = dstRow + SrcRow
Next

objWord.Quit 0 ' wdDoNotSaveChanges
Set objWord = Nothing
Set objDoc = Nothing

objExcel.ActiveWorkbook.SaveAs "C:\MyBook.xlsx"
objExcel.Quit
Set objExcel = Nothing
Set objSheet = Nothing

MsgBox "All table data copied from document to workbook!"

información relacionada