Estoy intentando generar un archivo de texto que contenga el nombre del archivo (incluida la ruta completa) y el tamaño del archivo para todos los archivos en un directorio particular y cualquiera de sus subdirectorios (es decir, de forma recursiva). Idealmente, no quiero comas en el tamaño del archivo (¡pero me conformaré con ellas!)
El siguiente comando lo hace pero sin el tamaño del archivo:
dir /b /s /a:-D > results.txt
Un resultado de ejemplo se vería así:
C:\Users\Martin\Pictures\Table\original\PC120013.JPG 227298
C:\Users\Martin\Pictures\Table\original\PC120014.JPG 123234
C:\Users\Martin\Pictures\Table\original\PC120015.JPG 932344
No creo que esto sea posible si se usa dirsolo, aunque me encantaría que me demuestren que estoy equivocado. ¿Existe otra forma de hacer esto, utilizando únicamente los comandos que están disponibles en el símbolo del sistema?
Respuesta1
Esto debería hacerlo:
@echo off & for /f %a in ('dir /s /b') do echo %~fa %~za
No es muy eficiente... ejecutarlo en carpetas que contienen una gran cantidad de archivos puede resultar complicado, así que pruébelo primero en carpetas pequeñas.
Del "¿para /?" texto de ayuda (usé 'a' en lugar de 'I')
In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:
%~I - expands %I removing any surrounding quotes (")
%~fI - expands %I to a fully qualified path name
%~dI - expands %I to a drive letter only
%~pI - expands %I to a path only
%~nI - expands %I to a file name only
%~xI - expands %I to a file extension only
%~sI - expanded path contains short names only
%~aI - expands %I to file attributes of file
%~tI - expands %I to date/time of file
%~zI - expands %I to size of file
%~$PATH:I - searches the directories listed in the PATH
environment variable and expands %I to the
fully qualified name of the first one found.
If the environment variable name is not
defined or the file is not found by the
search, then this modifier expands to the
empty string
The modifiers can be combined to get compound results:
%~dpI - expands %I to a drive letter and path only
%~nxI - expands %I to a file name and extension only
%~fsI - expands %I to a full path name with short names only
%~dp$PATH:I - searches the directories listed in the PATH
environment variable for %I and expands to the
drive letter and path of the first one found.
%~ftzaI - expands %I to a DIR like output line
Respuesta2
Alternativa n.° 1: FOR /R es más intuitiva que la n.° 2 para mí.
Alternativa #2: FOR /F soluciona el problema con los "espacios en los nombres" en la sugerencia de BrianAdkins.
Alternativa #3: FORFILES sería mi elección excepto que la ruta está entre comillas dobles.
Brian u otros gurús pueden tener una solución más elegante o pueden sugerir una docena de otras soluciones, pero estas tres funcionan. Intenté usar FOR TOKENS pero luego tuve que eliminar los encabezados y pies de página, así que volví al n.° 1. También consideré crear un pequeño archivo .bat y llamarlo, pero eso agrega otro archivo (aunque proporciona mayor flexibilidad, al igual que una función).
Probé todas las alternativas con directorios y nombres de archivos con espacios incrustados, un nombre de archivo de más de 200 caracteres, un nombre de archivo sin extensión y en la raíz de una unidad pequeña (solo por tiempo; un poco lento, tal como sugirió Brian, pero luego está buscando en el Explorador de Windows; es por eso que instalé la aplicación de búsqueda Everything).
Alternativa #1: PARA /R
Mejor(?)Mientras intentaba descubrir por qué la solución de Brian no funcionaba para mí, miré AYUDA PARA y decidí probar el enfoque /R. (Crear un archivo sería lo mismo que en la Alternativa n.° 2).
@echo off & for /R "c:\deletelater\folder with spaces" %A in (*.*) do echo %~fA %~zA
Ejemplo - Obras(directorio diferente al anterior para demostrar la recursividad)
@echo off & for /R "c:\deletelater" %A in (*.*) do echo %~fA %~zA
c:\DeleteLater\Name with Spaces.txt 19800676
c:\DeleteLater\NoSpacesLongName.txt 21745440
c:\DeleteLater\Folder with Spaces\2nd Name with Spaces.txt 5805492
c:\DeleteLater\Folder with Spaces\2ndNoSpacesLongName.txt 3870322
c:\DeleteLater\FolderNoSpaces\3rd Name with Spaces.txt 27874695
c:\DeleteLater\FolderNoSpaces\3rdNoSpacesLongName.txt 28726032
Alternativa #2: PARA /F
BrianAdkins sugirió:@echo off & for /f %a in ('dir /s /b') do echo %~fa %~za
Arespuesta corregidaes:
@echo off & for /f "delims=*" %A in ('dir /s /b') do echo %~fA %~zA
Amás completoLa respuesta con directorios suprimidos y salida (añadida) a un archivo es:
@echo Results on %DATE% for %CD% >> YourDirFile.txt & echo off & for /f "delims=*" %A in ('dir /s /b /a:-d') do echo %~fA %~zA >> YourDirFile.txt
Nota: "delims=*" especifica un carácter no permitido en los nombres de archivos.
Nota: el segundo comando también suprime directorios mediante /a:-d.
Nota: El nombre de la variable FOR se puso en mayúsculas para aclarar la distinción entre variable y parámetros de variable si alguien elige nombres de variable diferentes.
Nota: Se agregó al archivo solo para sonreír, ya que el OP solicitó la salida a un archivo.
Supongo que debería comprobar el estado de ECHO y restablecerlo también.
Problema: espacios en los nombres
La solución propuesta por Brian no maneja nombres de archivos y carpetas que contengan espacios (al menos no en mi configuración de Vista).
Ejemplo: incorrecto (Sin delimitaciones; incluye la supresión de directorio por OP pero con el tamaño antes y después del nombre del archivo para enfatizar)
Nombre y tamaño truncados (4 de 6 archivos incorrectos):
@echo off & for /f %A in ('dir /s /b /a:-d') do echo %~zA %~fA %~zA
C:\DeleteLater\Name
21745440 C:\DeleteLater\NoSpacesLongName.txt 21745440
C:\DeleteLater\Folder
C:\DeleteLater\Folder
C:\DeleteLater\FolderNoSpaces\3rd
28726032 C:\DeleteLater\FolderNoSpaces\3rdNoSpacesLongName.txt 28726032
Ejemplo: correcto (Nota enviada a la pantalla, no adjunta al archivo)
@echo off & for /f "delims=*" %A in ('dir /s /b /a:-d') do echo %~fA %~zA
C:\DeleteLater\Name with Spaces.txt 19800676
C:\DeleteLater\NoSpacesLongName.txt 21745440
C:\DeleteLater\Folder with Spaces\2nd Name with Spaces.txt 5805492
C:\DeleteLater\Folder with Spaces\2ndNoSpacesLongName.txt 3870322
C:\DeleteLater\FolderNoSpaces\3rd Name with Spaces.txt 27874695
C:\DeleteLater\FolderNoSpaces\3rdNoSpacesLongName.txt 28726032
Alternativa #3: FORFILES(Problema de cotización)
Esta solución proviene directamente de los dos últimos ejemplos de la documentación FORFILES ( forfiles /?).
FORFILES /S /M *.doc /C "cmd /c echo @fsize"
FORFILES /M *.txt /C "cmd /c if @isdir==FALSE notepad.exe @file"
Combinando estos ejemplos y escribiendo en un archivo se obtiene la respuesta (casi):
forfiles /s /c "cmd /c if @isdir==FALSE echo @path @fsize" >>ForfilesOut.txt
Tenga en cuenta que la ruta está entre comillas en el resultado.
No importa si se alterna con echo ono echo off.
Agregar una línea en blanco que separa cada directorio sería una extensión trivial del IF.
Precaución: ¡Usar la máscara /m *.*no devolverá archivos sin extensión (como el último archivo en el ejemplo)!
Aparte: Esto escribe un archivo en cada directorio con el contenido solo de ese directorio:
forfiles /s /c "cmd /c if @isdir==FALSE echo @path @fsize >>ForfilesSubOut.txt"no es lo que quería el OP, pero a veces es útil.
Ejemplo - Obras(pero con ruta completa entre comillas)
forfiles /s /c "cmd /c if @isdir==FALSE echo @path @fsize"
"c:\DeleteLater\Name with Spaces.txt" 19800676
"c:\DeleteLater\NoSpacesLongName.txt" 21745440
"c:\DeleteLater\Folder with Spaces\2nd Name with Spaces.txt" 5805492
"c:\DeleteLater\Folder with Spaces\2ndNoSpacesLongName.txt" 3870322
"c:\DeleteLater\FolderNoSpaces\3rd Name with Spaces.txt" 27874695
"c:\DeleteLater\FolderNoSpaces\3rdNoSpacesLongName.txt" 28726032
"c:\DeleteLater\MoreFiles\A really really long file name that goes on and on 123456789 asdfghjkl zxcvnm qwertyuiop and still A really really long file name that goes on and on 123456789 qwertyuiop and still further roughly 225 characters by now.txt" 447
"c:\DeleteLater\MoreFiles\New Text Document no extension" 0
Este ejemplo incluye un directorio adicional con un nombre de archivo muy largo y un nombre de archivo sin extensión.
Problema: Ruta entre comillas
Entonces, ¿existe una manera fácil de eliminar las comillas no deseadas (?) Según el ejemplo de OP y guardar la Alternativa n.° 3: FORFILES. (Pregunta retórica: ¿Son las citas una característica o un defecto?)
Respuesta3
El comando "du" me parece bastante útil y funciona tanto en Windows como en Unix (lo usé para comprobar si todos los archivos se copiaron al transferir muchos datos desde una PC con Windows a un servidor web Linux):
du -ah "C:\your_dir" > "C:\file_list.txt"
salidas:
15 C:\your_dir/.htaccess
608 C:\your_dir/folder/hello.txt
1.0 C:\your_dir/folder/subfolder/test.txt
1.0 C:\your_dir/folder/subfolder
1.2M C:\your_dir/folder/world.txt
1.2M C:\your_dir/folder
9.0 C:\your_dir/no_file_ending
11 C:\your_dir/sample document 1.txt
684K C:\your_dir/sample document 2 - äöüßÄÖÜáà.txt
1.9M C:\your_dir
Sin embargo, solo pude ver correctamente los caracteres especiales en el Bloc de notas, no en Notepad++ (debe ser alguna cosa de codificación ANSI/UTF-8, no hay tiempo para analizar exactamente ahora). Además, no encontré una solución para mostrar el tamaño después del nombre del archivo. Utilice las opciones "b" o "k" en lugar de "h" para mostrar el tamaño en bytes o kilobytes. Tuve algunos problemas al ejecutar el comando fuera de la carpeta que quiero analizar. Por lo tanto, es mejor ingresar el comando en el directorio correcto ("C:\your_dir" en este ejemplo) y especificarlo en el comando.
Respuesta4
Me doy cuenta de que esto requiere una utilidad adicional., pero puedes lograr esto de manera bastante sucinta usando elutilidad sfk:
sfk cwd +run -yes "sfk list -size -tab $qfile +toclip"
sfk fromclip > C:\_temp\sfk_list_output.txt
(Obtuve el enfoque usandoencadenamiento de comandos sfk aquí)