☰

Valores únicos en varias columnas

tag-icon • tag-icon microsoft-excel worksheet-function
Valores únicos en varias columnas

Tengo una hoja de cálculo con lo siguiente: -

Prod No     Store 1 $    Store 1 Qty    Store 2 Sale    Store 2 Qty  etc
A               4.00         1             7.50            2
B               0            0             15.00           1
C               4.00         2              -8             -1
D               5.00         1              5.00           1

Necesito obtener todos los precios únicos para cada número de pieza y luego totalizar la cantidad para cada precio, por ejemplo,

Prod No A has 4.00 1 unit and 7.50 2 units
Prod No B has 0.00 0 units and 15.00 1 unit
Prod No C has 4.00 2 units and -8 -1 unit
Prod No D has 5.00 2 units

También necesito una lista de los precios únicos y el total de cantidades para cada precio.

p.ej,

4.00 3 units
7.50 2 units
0.00 0 units
-8 -1 unit
15.00 1 unit
5.00 2 units

Respuesta1

En primer lugar, creo que tendrías más suerte a largo plazo si almacenaras tus datos en una forma más horizontal, por ejemplo

Store      Product     Qty    Sales
Store 1    A           1      4.00
Store 1    B           0      0.00
Store 1    C           2      4.00
Store 1    D           0      0.00

Es mucho más fácil realizar búsquedas en una sola columna que en pares de columnas.

(Dependiendo del tamaño y la escala, una base de datos de Access con tablas separadas de Tienda, Producto y Ventas podría ser incluso mejor que eso)

Dicho esto, si estás atascado con lo que tienes y puedes soportar una macro de VBA en tu hoja, puedes probar lo siguiente:

  1. Agregue un módulo de clase a su proyecto VBA, llamado Tuple, que contenga:

    Private szKey As String
Private nValue As Double

Public Property Get Key() As String
    Key = szKey
End Property
Public Property Let Key(newKey As String)
    szKey = newKey
End Property

Public Property Get Value() As Double
    Value = nValue
End Property
Public Property Let Value(newValue As Double)
    nValue = newValue
End Property

  2. Agregue un módulo normal, por ejemplo Module 1a su proyecto, que contenga:

    Public Function Summarize(ByRef rng As Range) As String
    If rng.Cells.Count Mod 2 = 1 Then Err.Raise 100, "", "Expected range of even cells"

    Dim coll As New Collection

    On Error Resume Next
    Dim flag As Boolean: flag = False
    Dim prevCel As Range, cel As Range: For Each cel In rng.Cells
        If flag Then
            Dim Key As String: Key = "" & prevCel.Value2
            coll(Key).Value = coll(Key).Value + cel.Value2

            If Err.Number <> 0 Then
                Err.Clear
                Dim t1 As New Tuple
                    t1.Key = "" & prevCel.Value2
                    t1.Value = cel.Value2
                    coll.Add t1, Key
                Set t1 = Nothing
            End If
        End If
        Set prevCel = cel
        flag = Not flag
    Next cel
    On Error GoTo 0

    Dim t2 As Variant: For Each t2 In coll
        If Len(Summarize) Then Summarize = Summarize & ", "
        Summarize = Summarize & Format(t2.Key, "#0.00") & " @ " & t2.Value
    Next t2
End Function

  3. Luego, en la hoja de trabajo, podrías ingresar una fórmula, como por ejemplo:

    ="Product " & $A2 & " has " & Summarize($B2:$I2)

    Asegúrese de sustituir el rango $B2:$I2 por uno que sea lo suficientemente amplio como para cubrir todos los números posibles de tiendas. También asegúrese de utilizar un rango de tamaño uniforme (porque los valores de Venta/Cantidad están en pares); de lo contrario, obtendrá un #VALUEerror.

información relacionada