☰

Obtenga el porcentaje de valores distintos dependiendo de la segunda columna

tag-icon • tag-icon microsoft-excel worksheet-function
Obtenga el porcentaje de valores distintos dependiendo de la segunda columna

Tengo una encuesta que envié a la gente. Una pregunta fue sobre su sexo y otra sobre si les duele la cabeza. Ahora tengo resultados en un archivo de Excel y estoy intentando analizarlo.
Pero tengo problemas para calcular una estadística.

ingrese la descripción de la imagen aquí

Lo que quiero es calcular qué porcentaje de personas que experimentan dolores de cabeza son hombres y qué porcentaje de ellos son mujeres.

Sé que el concepto es
# people that are men AND experience headaches /
# of people that experience headaches

¿Cómo obtengo esos porcentajes?

Respuesta1

Una normal countifno funciona con más de una columna como dependencia. Úselo SUMPRODUCTen su lugar.

  1. Esta fórmula contará todas las filas dondehombresYdolor de cabezaes verdad.

    =SUMPRODUCT((A1:A100=1)*(B1:B100=1))

    Tenga en cuenta que puede ampliar la fórmula para tener un tercio o más dependencias si lo desea »
    ...*(C1:C100=x)...

    Salida de ejemplo = 2

  2. Para obtener el recuento de personas con dolores de cabeza utilice COUNTIF, ya que aquí solo tenemos una columna para buscar

    COUNTIF(B:B,1)

    Salida de ejemplo = 6

  3. Ahora sólo tienes que combinar estas dos fórmulas

    =SUMPRODUCT((A1:A100=1)*(B1:B100=1)) / COUNTIF(B:B,1)
=SUMPRODUCT((A1:A100=2)*(B1:B100=1)) / COUNTIF(B:B,1)

    Salida de ejemplo = 2/6 = 0,333333 = 33,33 %
    Salida de ejemplo = 4/6 = 0,666667 = 66,67 %

    La primera fórmula es para hombres con dolor de cabeza, la segunda para mujeres con dolor de cabeza.

Existen algunas alternativas a la primera fórmula =SUMPRODUCT((A1:A100=1)*(B1:B100=1))que le darán el mismo resultado. Elige tu favorito:

  • {=SUM(IF((A1:A100=1)*(B1:B100=1),1))}

  • {=SUM((A1:A100=1)*(B1:B100=1))}

  • {=SUM(N(A1:A100&B1:B100=1&1))}

  • =COUNTIFS(A:A;1,B:B,1)» no disponible en Excel 2003

  • {=SUM((A:A=1)*(B:B=1))} » no disponible en Excel 2003

Observe que la mayoría de ellos sonfórmulas de matriz {...}que se ingresan con CTRL+ SHIFT+ENTER

Fuente

Respuesta2

Otra forma es usar una AVERAGEfunción como esta.

=AVERAGE(IF(B2:B100=1,IF(A2:A100=1,1,0)))

confirmado con CTRL+ SHIFT+ENTER

Cuando B2:B100 = 1 (dolores de cabeza experimentados), se devolverá 1 o 0 dependiendo de si son hombres o mujeres; el promedio le dará el porcentaje correcto.

información relacionada