☰

modo malvado '>' mal-shift-izquierda pierde la selección

tag-icon • tag-icon emacs evil
modo malvado '>' mal-shift-izquierda pierde la selección

¿Hay alguna razón por la que evil-mode evil-shift-left pierda la selección?

Es decir, me gustaría poder presionar '>' y '<' varias veces en la selección para desplazar el texto hacia la izquierda y hacia la derecha.

Aquí está la implementación a continuación. ¿De todos modos agregar un consejo para cambiar este comportamiento?

evil-commands.el

(evil-define-operator evil-shift-right (beg end &optional count)
  "Shift text from BEG to END to the right.
The text is shifted to the nearest multiple of `evil-shift-width'
\(the rounding can be disabled by setting `evil-shift-round').
See also `evil-shift-left'."
  :type line
  (interactive "<r><vc>")
  (let ((beg (set-marker (make-marker) beg))
        (end (set-marker (make-marker) end)))
    (dotimes (i (or count 1))
      (if (not evil-shift-round)
          (indent-rigidly beg end evil-shift-width)
        (let* ((indent
                (save-excursion
                  (goto-char beg)
                  (evil-move-beginning-of-line nil)
                  (while (and (< (point) end) (looking-at "[ \t]*$"))
                    (forward-line))
                  (if (> (point) end) 0
                    (current-indentation))))
               (offset (- evil-shift-width (mod indent evil-shift-width))))
          (indent-rigidly beg end offset))))
    (set-marker beg nil)
    (set-marker end nil)))

Respuesta1

Esto sobrecarga el comportamiento actual para volver a seleccionar (que se encuentra endjoyner/dotfiles/emacs/lisp/evil-config.el#L36-L40).

; Overload shifts so that they don't lose the selection
(define-key evil-visual-state-map (kbd ">") 'djoyner/evil-shift-right-visual)
(define-key evil-visual-state-map (kbd "<") 'djoyner/evil-shift-left-visual)
(define-key evil-visual-state-map [tab] 'djoyner/evil-shift-right-visual)
(define-key evil-visual-state-map [S-tab] 'djoyner/evil-shift-left-visual)

(defun djoyner/evil-shift-left-visual ()
  (interactive)
  (evil-shift-left (region-beginning) (region-end))
  (evil-normal-state)
  (evil-visual-restore))

(defun djoyner/evil-shift-right-visual ()
  (interactive)
  (evil-shift-right (region-beginning) (region-end))
  (evil-normal-state)
  (evil-visual-restore))

Respuesta2

Muy similar a la respuesta ya proporcionada por @avsej, pero su uso call-interactivelygarantiza que evil-shift-{left,right} reciba todos sus argumentos (por ejemplo COUNT). Por ejemplo,

(defun my-visual-shift-left ()
  (interactive)
  (call-interactively 'evil-shift-left)
  (evil-normal-state)
  (evil-visual-restore))

De esa manera, aún puedes sangrar más de una unidad a la vez (p. ej 4>.).

información relacionada