☰

Encontrar valores únicos en 3 columnas

tag-icon • tag-icon microsoft-excel-2010
Encontrar valores únicos en 3 columnas

Tengo 3 columnas en excel. Quiero encontrar valores únicos en las columnas A, B y C.

Entonces:

  1. Al mirar en la columna A, quiero encontrar los valores únicos que no están en B o C.
  2. Al mirar en la columna B, quiero encontrar valores únicos que no estén en la columna A o C.
  3. Al buscar en la columna C, quiero encontrar valores únicos que no estén en la columna A o B.

Esto es lo que puse en la columna A.

=IF(OR(MATCH(A3,$B$3:$B$631,0),(MATCH(A3,$C$3:$C$408,0))),"Match",A3)

Esto es lo que puse en la columna B.

=IF(OR(MATCH(B3,$A$3:$A$857,0),(MATCH(B3,$C$3:$C$408,0))),"Match",B3)

Esto es lo que puse en la columna C.

=(IF(OR(MATCH(C3,$A$3:$A$857,0),(MATCH(C3,$B$3:$B$631,0))),"Match",C3)

Esto me da valores duplicados en las tres columnas. Necesito que sean únicos. Quizás estoy haciendo esto muy complicado. ¿Alguna idea de como hacerlo?

El ejemplo de la tabla:

A   B   C
1   2   2
2   3   3
3   7   7
4   8   11
5   9   12
6   10  13

En este caso, quiero el # único en cada columna. Entonces, para la columna A, los valores únicos que no están en las columnas B o C son = a 1,4,5,6. En la columna B los valores únicos, que no están en A o C, son =8,9, 10. En la columna C los valores únicos, que no están en B o C son = 11, 12, 13. Quiero hacer un fórmula en las columnas D, E, F para estas tres fórmulas.

A B C 1 2 2 2 3 3 3 7 7 4 8 11 5 9 12 6 10 13

En este caso, quiero el # único en cada columna. Entonces, para la columna A, los valores inquietos que no están en las columnas B o C son = a 1,4,5,6. En la columna B los valores únicos, que no están en A o C, son =8,9, 10. En la columna C los valores únicos, que no están en B o C son = 11, 12, 13. Quiero hacer un fórmula en las columnas D, E, F para estas tres fórmulas.

Respuesta1

Puede utilizar una fórmula matricial † como la siguiente en D1:

=IFERROR(INDEX($A$1:$A$6,SMALL(IF(ISERROR(MATCH($A$1:$A$6,$B$1:$B$6,0))*ISERROR(MATCH($A$1:$A$6,$C$1:$C$6,0)),ROW($A$1:$A$6)),ROW())),"")

Las fórmulas en las otras columnas son similares:

E1:

=IFERROR(INDEX($B$1:$B$6,SMALL(IF(ISERROR(MATCH($B$1:$B$6,$A$1:$A$6,0))*ISERROR(MATCH($B$1:$B$6,$C$1:$C$6,0)),ROW($B$1:$B$6)),ROW())),"")

F1:

=IFERROR(INDEX($C$1:$C$6,SMALL(IF(ISERROR(MATCH($C$1:$C$6,$A$1:$A$6,0))*ISERROR(MATCH($C$1:$C$6,$B$1:$B$6,0)),ROW($C$1:$C$6)),ROW())),"")

Y de su tabla de ejemplo, obtengo esto:

ingrese la descripción de la imagen aquí

Si su fórmula comienza en una fila diferente a la primera, será necesario cambiar un poco la fórmula porque su uso ROW()depende de la fila en la que se coloca la fórmula.

† Nota: Para usar la fórmula, debe mantener presionado Ctrl+ Shifty luego presionar Enterdespués de insertarla.

información relacionada