Elimina un nuevo borrador de correo electrónico que estás editando en Outlook

Question

Usando Outlook 2013. Cuando redactas un nuevo correo electrónico, generalmente hay una manera de deshacerte de él rápidamente en caso de que ya no quieras enviarlo. ¿Hay alguna manera de hacer esto en Outlook?

Intenté cerrar el mensaje (y no guardarlo/conservarlo cuando se me solicita), pero eso crea un nuevo elemento no leído en mi carpeta de elementos eliminados, lo que hace que se ilumine como un árbol de Navidad. Luego tengo que ir manualmente a esa carpeta para limpiar el borrador.

Estoy buscando algo como el ícono de la papelera de Gmail. Una forma sencilla e indolora de deshacerse del mensaje de una vez por todas con un solo clic. (Hay ocasiones en las que quiero guardar un borrador, por si acaso, pero la mayoría de las veces no lo hago).

ACTUALIZACIÓN: Puede exponer un botón "Eliminar" en la "Barra de herramientas de acceso rápido" en la parte superior, lo que hace que se elimine el elemento del mensaje. Esto funciona en el momento en que recién comienza a escribir un nuevo correo electrónico. Al hacer clic en eliminar se destruye el mensaje después de la advertencia obligatoria. Pero (!), tan pronto como el correo electrónico se guarda automáticamente (después de un tiempo), ingresa a la carpeta Borradores. Eliminar el mensaje en este punto MANTIENE el mensaje ya que simplemente se mueve a Elementos eliminados.

¿Existe alguna configuración que pueda hacer que Outlook imite el botón de la papelera de Gmail al crear un nuevo correo electrónico? Es un caso de uso tan simple: "No quiero enviar el correo electrónico que acabo de comenzar, cambié de opinión, deshacerme de él, borrar todo rastro del mismo". ¿Es esta otra característica deficiente de Microsoft?

Answer 1

1. Puedes escribir un script VBA que haga algo comoDesecharmarcando el mensaje como leído y eliminándolos paraObjetos eliminados. Después de eso, coloque el botón en la ventana del mensaje que ejecuta la macro (usando Personalizar cinta -> Macros).

Algo como esto:

Sub Discard()
    On Error Resume Next
    Dim objItem As MailItem

    Set objInspector = ActiveInspector
    If Not objInspector Is Nothing Then
        Set objItem = objInspector.CurrentItem
        If Not objItem Is Nothing And Not objItem.Sent Then
            objItem.UnRead = False
            objItem.Delete
        End If
    End If
End Sub

2. GratisComplemento de ajustes rápidosPuede marcar todos los elementos eliminados como leídos automáticamente.
3. SHIFT+ DELelimina los mensajes seleccionados en la lista de mensajes sin colocarlosObjetos eliminados.

Answer 2

Descubrí una manera de marcar automáticamente los elementos que se agregan a la carpeta eliminada como leídos. Con esta solución, no es necesario agregar un botón que esté vinculado a una macro.

Simplemente agregue el siguiente código a "ThisOutlookSession" en el editor VBA:

Private WithEvents deletedItems As Outlook.Items

Private Sub Application_Startup()
    Dim olApp As Outlook.Application
    Dim objNS As Outlook.NameSpace
    Set olApp = Outlook.Application
    Set objNS = olApp.GetNamespace("MAPI")
    'Default folder for deleted items
    Set deletedItems = objNS.GetDefaultFolder(olFolderDeletedItems).Items
End Sub

Private Sub deletedItems_ItemAdd(ByVal Item As Object)
    Dim deletedEmail As Outlook.MailItem
    If TypeName(Item) = "MailItem" Then
        Set deletedEmail = Item
        deletedEmail.UnRead = False
    End If
End Sub

Deberá reiniciar Outlook para que funcione.

Tenga en cuenta que se aplicará a todos los correos electrónicos eliminados y no solo a los borradores.

Answer 3

La versión actual de Outlook tiene un montón de botones de acción en el medio del borde derecho de la ventana y hay una X roja para descartar.

Estoy de acuerdo en que la interfaz de usuario de Outlook es bastante terrible y poco intuitiva, pero no debería ser necesario crear macros sólo para descartar un borrador de mensaje.

Answer 4

La versión que terminé usando tiene un código para eliminar el elemento de correo de Elementos eliminados después de eliminarlo.

Sub Discard()
    On Error Resume Next
    Dim objItem As MailItem

    Set objInspector = ActiveInspector
    If Not objInspector Is Nothing Then
        Set objItem = objInspector.CurrentItem
        If Not objItem Is Nothing And Not objItem.Sent Then
            'no EntryID exists for freshly created mail, but does for a draft
            MyEntryId = objItem.EntryID
            objItem.UnRead = False
            objItem.Delete
            If Not MyEntryId = "" Then
                Dim oDeletedItems As Outlook.Folder
                'Obtain a reference to deleted items folder
                Set oDeletedItems = Application.Session.GetDefaultFolder(olFolderDeletedItems)
                'Delete last item from Deleted Items
                oDeletedItems.Items.Item(oDeletedItems.Items.Count).Delete
            End If
        End If
    End If
End Sub