Mover los últimos N archivos de la carpeta en Windows 8.1

Question

Me preguntaba: ¿existe una forma agradable y elegante en Windows 8.1 de mover los últimos N archivos de una carpeta a otra además de escribir un programa para hacerlo?

Editar: N es, por ejemplo, 100 y los archivos se ordenan por nombre.

Answer 1

¿Cómo muevo los últimos N archivos de una carpeta?

N es, por ejemplo, 100 y los archivos se ordenan por nombre.

Utilice el siguiente archivo por lotes (test.cmd):

@echo off
rem parameters
rem %1 number of files to move
rem %2 source directory
rem %3 target directory
Setlocal EnableDelayedExpansion
rem initialise number of files
set count=0
rem count files
for /f "delims=" %%a in ('dir %2 /a-d /b /O:N') do @(set /a count+=1 >nul)
rem set number of files to skip (not move)
set /a "skip=count-%1"
rem move the files
for /f "skip=%skip% delims=" %%a in ('dir %2 /a-d /b /O:N') do echo move %2\%%a %3\%%a

Elimine el echode do echo move...cuando esté satisfecho de que el archivo por lotes esté funcionando a su satisfacción.

Uso:

test N Source Target

Dónde:

• Nnúmero de archivos para mover
• Sourcedirectorio fuente
• Targetdirectorio de destino

Ejemplo:

C:\test>dir
 Volume in drive C has no label.
 Volume Serial Number is C8D0-DF1E

 Directory of C:\test

31/05/2015  11:31    <DIR>          .
31/05/2015  11:31    <DIR>          ..
26/05/2015  18:20               117 address.out
26/05/2015  18:16               265 data.txt
31/05/2015  11:25    <JUNCTION>     junction [f:\test]
31/05/2015  11:31    <DIR>          sub
31/05/2015  18:16               449 test.cmd
               3 File(s)            831 bytes
               4 Dir(s)  95,480,258,560 bytes free

C:\test>test 1 . c:\temp
move .\test.cmd c:\temp\test.cmd
C:\test>

---

Otras lecturas

• Un índice AZ de la línea de comando CMD de Windows- Una excelente referencia para todo lo relacionado con la línea cmd de Windows.