☰

Extraer rar multiparte, eliminando partes a medida que se extraen

tag-icon • tag-icon windows compression rar
Extraer rar multiparte, eliminando partes a medida que se extraen

Tengo un rar multiparte de 80GB descomprimido. Tengo 5 GB de espacio libre y cada parte del archivo rar tiene 2 GB.

Lo que busco es extraer una parte, borrarla, extraer la siguiente, y así sucesivamente, para utilizar como máximo 5 GB más en el proceso de extracción y no agotar todo mi espacio en disco.

Respuesta1

IMPORTANTE:

  • este guiónVOLUNTADelimine las partes que se hayan extraído independientemente del resultado final, por lo que si el proceso se detiene por una parte faltante o dañada, no podrá comenzar de nuevo
  • Abra el bloc de notas, pegue el siguiente código y guárdelo como_unrar.vbsen la misma carpeta con tus archivos rar.
  • ColocarUnRAR_Full_Path,Primera parteyCarpeta_destino, asegúrese de conservar las comillas.

La secuencia de comandos:

UnRAR_Full_Path = "c:\program files\winrar\unrar.exe"
First_Part = "YourArchiveName.part001.rar"
Target_Folder = "ExtractedFiles\"

mf_command = AddQuotes(UnRAR_Full_Path) & " x " & AddQuotes(First_Part) & " " & AddQuotes(Target_Folder)
mf_LZerosSplit = Split(First_Part, ".")
mf_LZerosPart = Mid(mf_LZerosSplit(UBound(mf_LZerosSplit)-1), 5)
If UBound(mf_LZerosSplit) > 3 Then
    WScript.Echo ("Too Lazy to deal with names the contains dots, only 2 are allowed. one before 'part' and one before 'rar'")
    WScript.Quit 1
End If
mf_LZ_UnderTen = ""
mf_LZ_UnderHundred = ""
mf_LZ_UnderThousand = ""

If Len(mf_LZerosPart) = 2 Then
    mf_LZ_UnderTen = "0"

ElseIf Len(mf_LZerosPart) = 3 Then
    mf_LZ_UnderTen = "00"
    mf_LZ_UnderHundred = "0"

ElseIf Len(mf_LZerosPart) = 4 Then
    mf_LZ_UnderTen = "000"
    mf_LZ_UnderHundred = "00"
    mf_LZ_UnderThousand = "0"
End If 
Set objShell = CreateObject("WScript.Shell")
Set objWshScriptExec = objShell.Exec(mf_command)
Set objStdOut = objWshScriptExec.StdOut

While Not objStdOut.AtEndOfStream
    strLine = objStdOut.ReadLine

    'WScript.Echo (strLine)

        If InStr(strLine,"Extracting from") Then
            mf_filename = Mid(strLine, 17)
            mf_partnameSplit = Split(mf_filename, ".")
            mf_partname = mf_partnameSplit(1)
            mf_partnumber = Mid(mf_partname , 5)
            If mf_partnumber > 1 Then
                mf_numtodel = mf_partnumber-1
                mf_LeadingZeros = ""
                If mf_numtodel < 10 Then
                    mf_LeadingZeros = mf_LZ_UnderTen
                ElseIf mf_numtodel < 100  Then
                    mf_LeadingZeros = mf_LZ_UnderHundred
                ElseIf mf_numtodel < 1000  Then
                    mf_LeadingZeros = mf_LZ_UnderThousand
                End If
                mf_filetodel = mf_partnameSplit(0) & ".part" & mf_LeadingZeros & mf_numtodel & ".rar"

                'WScript.Echo ("NOW DELETING: " & mf_filetodel)

                Set obj = CreateObject("Scripting.FileSystemObject")
                obj.DeleteFile(mf_filetodel)
            End If
        ElseIf InStr(strLine,"All OK") Then
            WScript.Echo ("looks like All Ok, Delete the Last part and Have a nice day :)")
        End If
Wend

Function AddQuotes(strInput)
    AddQuotes = Chr(34) & strInput & Chr(34)
End Function

Opcion uno:Silencioso

ejecutar el_unrar.vbsarchivo haciendo doble clic en él

Opción dos:Recomendado

eliminar el'desde el inicio de

'WScript.Echo (strLine)

'WScript.Echo ("Deleting: " & mf_filetodel)

abra cmd, diríjase a su carpeta y escriba"cscript _unrar.vbs"

  • usandoWScript.Echosincscriptaparecerán demasiados cuadros de mensajes molestos

Este script funciona leyendo la salida estándar de UnRAR.exe.

EDITAR

Se mejoró el script para que funcione automáticamente con cualquier estructura de nombre y con cualquier número de partes hasta 9999 partes. y trabajar con archivos heredados que no contienen ceros a la izquierda.

información relacionada