☰

Cómo aplicar una fórmula macro/vba a más de una celda

tag-icon • tag-icon vba macros
Cómo aplicar una fórmula macro/vba a más de una celda

He ingresado lo siguiente:

Private Sub Worksheet_Change(ByVal Target As Range)

If Target.Address = "$V$2" Then
    Range("U2") = Range("V2") * Range("O2")
End If

If Target.Address = "$U$2" Then
    Range("V2") = Range("U2") / Range("O2")
End If

End Sub

.....Sin embargo, esto sólo funciona en las celdas u2 y v2. Necesito que esta fórmula se ejecute hasta la columna U y la columna V.

Se agradece cualquier ayuda.

Respuesta1

Si entiendo correctamente, podrías usar algo como esto.

Private Sub Worksheet_Change(ByVal Target As Range)

    'Don't apply to column headers
    If Target.Row = 1 Then Exit Sub

    'Make changes to anything in Column V (22)
    If Target.Column = 22 Then
        If IsNumeric(Range("V" & Target.Row)) And IsNumeric(Range("O" & Target.Row)) Then
            Range("U" & Target.Row) = Range("V" & Target.Row) * Range("O" & Target.Row)
        End If
    End If

    'Make changes to anything in Column U (21)
    If Target.Column = 21 Then
        If IsNumeric(Range("U" & Target.Row)) And IsNumeric(Range("O" & Target.Row)) And Range("O" & Target.Row) <> 0 Then
            Range("V" & Target.Row) = Range("U" & Target.Row) / Range("O" & Target.Row)
        End If
    End If

End Sub

Este evento se activa cada vez que se cambia una celda. Como tal, verificará en qué columna se encuentra el cambio: If Target.Column = 22 Then... Si la columna es 22 (representación numérica de la columna V), avanzará al resto del código, que consiste en cambiar U, V y O usando el Target.Row, eso es decir, el número de fila de la celda modificada.

Editar: Se agregó la verificación Dividir por cero y verificar para asegurarse de que todos los elementos ingresados ​​sean en realidad números y no letras/símbolos.

Respuesta2

Considerar:

Private Sub Worksheet_Change(ByVal Target As Range)
   If Target.Row = 1 Then Exit Sub
   If Intersect(Target, Range("U:V")) Is Nothing Then Exit Sub
   Application.EnableEvents = False
      If Not Intersect(Target, Range("V:V")) Is Nothing Then
         Target.Offset(0, -1).Value = Target.Value / Range("O" & Target.Row).Value
      Else
         Target.Offset(0, 1).Value = Target.Value / Range("O" & Target.Row).Value
      End If
   Application.EnableEvents = True
End Sub

Nota: Esto excluye la primera fila.

información relacionada