Extraiga varias subcadenas de la celda de Excel

Question

Tengo una columna con un formato horrible donde cada celda puede contener cero o una o más entradas como las siguientes (ésta contiene dos):

ACTI-U-9754 - Some description MDCF-U-9791 - Some other description

Necesito extraer las cadenas de 11 caracteres en una columna separada, preferiblemente con una fórmula. Para la celda de arriba debería verse así:

ACTI-U-9754
MDCF-U-9791

No he encontrado ejemplos que aborden este escenario particular.

Answer 1

Me temo que no se me ocurrió un método de fórmula simple; sin embargo, aquí hay un método VBA que usa RegEx, en caso de que le resulte útil. El patrón RegEx supone que los códigos siempre serán los mismos 4 letters - 1 letter - 4 digits; por supuesto, puede modificarlos según sea necesario. Si la suposición de letras y dígitos es incorrecta, pero el formato es siempre 4-1-4, puedes usar .{4}\-.\-.{4}en su lugar:

Sub GetCodes()
    Dim strPattern: strPattern = "\w{4}\-\w\-\d{4}"   'Pattern to match
    Dim colNumber: colNumber = 1                        'Column number containing strings (In this case, 1, for column A)
    Dim rowCount: rowCount = 1                          'Row number to start from
    Range("B1").Select                                  'Cell to start new column from

    'Create a new RegEx engine instance
    Dim rgx: Set rgx = CreateObject("vbscript.regexp")

    'Set out RegEx instance to allow Global (More than 1 result per text), MultiLine (Incase there are any carriage returns in the cell), IgnoreCase (Allow both upper and lowercase, which isn't needed with \w but included to be sure) and Pattern, the patter defined above.
    With rgx
        .Global = True
        .MultiLine = True
        .IgnoreCase = True
        .Pattern = strPattern
    End With

    'Begin a loop that ends once we hit an empty cell
    Do
        'Get all our RegEx matches and store them in rgxMatches
        Dim rgxMatches: Set rgxMatches = rgx.Execute(Cells(rowCount, colNumber).Value)
        Dim rgxMatch
        'Loop through our matches
        For Each rgxMatch In rgxMatches
            'Write the match into the active cell
            ActiveCell.Value = rgxMatch.Value
            'Go down one row, ready to write the next cell if there is one
            ActiveCell.Offset(1, 0).Select
        Next

        'Increment our row count so the next loop uses the next row
        rowCount = rowCount + 1
    Loop Until IsEmpty(Cells(rowCount, colNumber))

    'Clean up after
    Set rgx = Nothing
    Set rgxMatches = Nothing
End Sub