☰

¿Cómo configuro Unicode-8 como predeterminado en LibreOffice en Windows 10?

tag-icon • tag-icon windows-10 libreoffice
¿Cómo configuro Unicode-8 como predeterminado en LibreOffice en Windows 10?

Cuando uso LibreOffice Calc y guardo mi archivo como .csv, LibreOffice sugiere Europa occidental como codificación predeterminada. Sin embargo, quiero codificación Unicode-8.

¿Cómo configuro Unicode-8 como predeterminado en LibreOffice en Windows 10?

Respuesta1

Al mirar mi copia de LibreOffice v5.0.x, no parece tener una configuración predeterminada. Sin embargo, mirando a mi alrededor encontré un ejemplo de una macro que puedes usar aquí para guardar en UTF8.

https://forum.openoffice.org/en/forum/viewtopic.php?f=45&t=19695

y la otra macro para indicarle que utilice un cuadro de diálogo del Selector de archivos desde

https://forum.openoffice.org/en/forum/viewtopic.php?f=25&t=36441

Aquí está el código completo...

Function fOpenFile() as String

   Dim oFileDialog as Object
   Dim iAccept as Integer
   Dim sPath as String
   Dim InitPath as String
   Dim oUcb as object
   Dim filterNames(3) as String

   filterNames(0) = "*.csv"
   'filterNames(1) = "*.png"
   'filterNames(2) = "*.jpg"

   GlobalScope.BasicLibraries.LoadLibrary("Tools")
   'Note: The following services must be called in the following order,
   ' otherwise the FileDialog Service is not removed.
   oFileDialog = CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
   oUcb = createUnoService("com.sun.star.ucb.SimpleFileAccess")

   AddFiltersToDialog(FilterNames(), oFileDialog)
   'Set your initial path here!
   InitPath = ConvertToUrl("C:\")

   If oUcb.Exists(InitPath) Then
      oFileDialog.SetDisplayDirectory(InitPath)
   End If

   iAccept = oFileDialog.Execute()
   If iAccept = 1 Then
      sPath = oFileDialog.Files(0)
      fOpenFile = sPath
   End If
   oFileDialog.Dispose()

End Function
Sub SaveAsCsvUTF8
    Dim Propval(1) as New com.sun.star.beans.PropertyValue
    Propval(0).Name = "FilterName"
    Propval(0).Value = "Text - txt - csv (StarCalc)"
    Propval(1).Name = "FilterOptions"
    ' field sep(44 - comma), txt delim (34 - dblquo), charset (0 = system, 76 - utf8), first line (1 or 2) 
    Propval(1).Value = "44,34,76,1" 
    Doc = ThisComponent
    Filename = fOpenFile()
    FileURL = convertToURL(FileName)
    Doc.StoreAsURL(FileURL, Propval())
End Sub

Asígnalo a un atajo y listo.

PD: Si el archivo ya está en UTF8, debería respetarlo.

HT

información relacionada