¿Cómo extraer una columna específica de un libro diferente almacenado en una carpeta usando VBA?

Question

Supongamos que tengo libros de trabajo y cada libro de trabajo contiene hojas de trabajo individuales y todas las hojas de trabajo tienen el mismo número de filas y columnas... de cada hoja de trabajo... Quiero extraer un nombre de columna "10-11 de mayo". El nombre de esta columna es común para cada hoja de trabajo. Entonces, ¿cómo puedo extraer una columna "10-11 de mayo" de cada libro almacenado en la misma carpeta?

Por ejemplo :

Cada hoja de trabajo contiene el mismo número de filas y columnas, filas = 453 y columnas = 55. De esta imagen de muestra quiero extraer la columna "10-11 de mayo" de todos los libros almacenados en la misma carpeta y en hojas de trabajo diferentes.

Answer 1

¿Es esto lo que quieres? la fuente es dehttps://msdn.microsoft.com/en-us/library/office/gg549168(v=office.14).aspx

Sub MergeAllWorkbooks()
    Dim SummarySheet As Worksheet
    Dim FolderPath As String
    Dim NRow As Long
    Dim FileName As String
    Dim WorkBk As Workbook
    Dim SourceRange As Range
    Dim DestRange As Range

    ' Create a new workbook and set a variable to the first sheet. 
    Set SummarySheet = Workbooks.Add(xlWBATWorksheet).Worksheets(1)

    ' Modify this folder path to point to the files you want to use.
    FolderPath = "C:\Users\Peter\invoices\"

    ' NRow keeps track of where to insert new rows in the destination workbook.
    NRow = 1

    ' Call Dir the first time, pointing it to all Excel files in the folder path.
    FileName = Dir(FolderPath & "*.xl*")

    ' Loop until Dir returns an empty string.
    Do While FileName <> ""
        ' Open a workbook in the folder
        Set WorkBk = Workbooks.Open(FolderPath & FileName)

        ' Set the cell in column A to be the file name.
        SummarySheet.Range("A" & NRow).Value = FileName

        ' Set the source range to be A9 through C9.
        ' Modify this range for your workbooks. 
        ' It can span multiple rows.
        Set SourceRange = WorkBk.Worksheets(1).Range("A9:C9")

        ' Set the destination range to start at column B and 
        ' be the same size as the source range.
        Set DestRange = SummarySheet.Range("B" & NRow)
        Set DestRange = DestRange.Resize(SourceRange.Rows.Count, _
           SourceRange.Columns.Count)

        ' Copy over the values from the source to the destination.
        DestRange.Value = SourceRange.Value

        ' Increase NRow so that we know where to copy data next.
        NRow = NRow + DestRange.Rows.Count

        ' Close the source workbook without saving changes.
        WorkBk.Close savechanges:=False

        ' Use Dir to get the next file name.
        FileName = Dir()
    Loop

    ' Call AutoFit on the destination sheet so that all 
    ' data is readable.
    SummarySheet.Columns.AutoFit
End Sub