Asignar el archivo por lotes a una tecla de acceso rápido

Asignar el archivo por lotes a una tecla de acceso rápido

En el Explorador de Windows, la configuraciónMostrar archivos, carpetas y unidades ocultosse puede habilitar y deshabilitar en Organise > Folder and search options > View.

¿Existe otra forma más rápida de habilitar/deshabilitar esta configuración? Algo a través de la línea de comando sería ideal, pero estoy abierto a todas las sugerencias que sean más rápidas o menos engorrosas.

Respuesta1

Estas configuraciones están en el Registro en esta clave:

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced

Para mostrar elementos ocultos, configúrelo Hiddenen 1 (para ocultarlos, configúrelo en 2). Para mostrar elementos del sistema/superocultos, configúrelo ShowSuperHiddenen 1 (0 para ocultar). Como estamos jugando directamente con el Registro, es necesario reiniciar Explorer.

Para lograr todo eso y permitir la visualización de todo, puede usar estos comandos por lotes:

reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v Hidden /t REG_DWORD /d 1 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v ShowSuperHidden /t REG_DWORD /d 1 /f
powershell -c gps 'explorer' ^| stop-process

Si prefiere evitar PowerShell, esto también debería funcionar para eliminar Explorer:

taskkill /im explorer.exe /f

Si Explorer no se reinicia automáticamente en su sistema, simplemente ejecútelo explorerpara recuperar su barra de tareas.

Respuesta2

Decidí tomar las claves y los comandos que Ben me proporcionó y escribir un único archivo por lotes que activa o desactiva los valores Hiddeny ShowSuperHiddenjuntos.

Alternar archivos ocultos/súper ocultos con un archivo por lotes

Puededescargue ToggleHidden.bat aquí, pero si prefieres copiar el script en un archivo .bato .cmdtú mismo, aquí tienes el código fuente:

@echo off
REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "Hidden" | Find "0x0"
If %ERRORLEVEL% == 0 goto show
IF %ERRORLEVEL% == 1 goto hide
goto :error

:show
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /f /d 1 > NUL
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /f /d 1
goto restart

:hide
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /f /d 0 > NUl
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /f /d 0
goto restart

:error
echo There was an error! Check the script.
pause
goto :eof

:restart
taskkill /f /im explorer.exe
start explorer

Un desglose de lo que hace el script: consulta los datos del Hiddenvalor; si está desactivado, lo activa y lo activa ShowSuperHidden. Si ya está activado, lo activa y ShowSuperHiddendesactiva. Decidí diseñar el script de esta manera porque es raro que yo personalmente necesite ver archivos ocultos sin ver también los archivos del sistema, pero puedes cambiar este comportamiento si lo prefieres. 1

Después de habilitar o deshabilitar estos valores de registro, el script finaliza y reinicia el proceso del explorador de Windows. Si, por alguna razón, Hiddenel comando no puede determinar el valor de queryentonces el script se interrumpe y emite un error antes de salir.

Asignar el archivo por lotes a una tecla de acceso rápido

Para satisfacer mis criterios de máxima comodidad, coloqué el ToggleHidden.batarchivo recién creado en algún lugar de mi computadora y lo uséAutoHotKeypara asignar una combinación de teclas de acceso rápido para ejecutarla. Hice esto agregando lo siguiente a mi script AHK existente:

Ctrl & H::
Run PATH\TO\FILE
Return

Utilicé AutoHotKey aquí porque ya lo uso para propósitos similares y lo encuentro como el método más útil para asignar teclas de acceso rápido para ejecutar mis programas, pero si prefieres no tener que instalar AHK para este paso, también puedes usareste método nativo de Windows para asignar teclas de acceso rápido a un programa.

Ahora puedo usar la combinación de teclas de acceso rápido Ctrl+ Hpara ocultar y mostrar u ocultar rápidamente archivos ocultos/del sistema a mi conveniencia... y funciona.hermosamente, si lo digo yo mismo.


1 Si planea seguir este camino, vale la pena señalar que, en el ecosistema de Windows, los archivos/carpetas superocultos actúan como un subconjunto de archivos/carpetas ocultos.

Lo que esto significa cuando se trata de estos dos valores de registro es que puede habilitar el Hiddenvalor sin habilitarlo ShowSuperHidden, pero no puede habilitarlo ShowSuperHiddensin habilitarlo Hidden; Al hacerlo, solo se mostrarán elementos normales, porque Windows considera los elementos superocultos como un tipo de elemento oculto, y si los elementos ocultos están ocultos, también lo están. En pocas palabras: si planeas encender ShowSuperHidden, debes asegurarte de encenderlo Hiddenjunto con él.

Respuesta3

La opción mostrar carpeta oculta es específicamente algo que forma parte del Explorador.

Aunque en la línea de comandos puede usar los comandos attribo dir /ahpara ver archivos ocultos, no puede controlar la configuración oculta desde la línea de comandos a menos que primero revise bastante. Básicamente, esta configuración se almacena en el registro y puede modificar el registro desde la línea de comandos. Pero será mucho más engorroso seguir este camino que cambiar rápidamente la configuración en el explorador.

Si esto es algo que va a hacer con frecuencia, sería más rápido encontrar la configuración en el registro y almacenarla en un archivo .reg, porque entonces puede hacer doble clic en los dos archivos .reg para habilitarlo y deshabilitarlo.

Desafortunadamente, no sé en qué parte del registro se encuentra. Sólo sé que está en la colmena HKCU, pero no dónde exactamente.

Si actualiza a Windows 10, esta configuración se puede encontrar directamente desde la pestaña Ver.

Respuesta4

Al utilizar un software gratuito y modificar ligeramente el script, ahora puedo alternar entre archivos ocultos.yrestaurar cualquier ventana de carpeta del explorador que tuviera abierta.

Primero, descargue la aplicación gratuita desde aquí:

https://www.sordum.org/9192/restart-explorer-v1-4/

extraer y mover mover la carpeta Rexplorer comprimida aC:\Archivos de programa

Luego realice el siguiente cambio en el script por lotes anterior:

:restart
start "" "C:\Program Files\Rexplorer\Rexplorer_x64.exe"
exit

Esto hará que la aplicación Rexplorer_x64.exe reinicie explorer.exe y restaure cualquier carpeta que tenga abierta en lugar de simplemente cerrar y reiniciar el explorador.

información relacionada