Una tecla de acceso rápido para mover un archivo a través de directorios (MacOS)

Question

¿Hay teclas de acceso rápido para mover carpetas hacia arriba o hacia abajo a través de carpetas y subcarpetas principales en MacOS?

Por ejemplo, en este ejemplo sencillo quiero mover el archivo 1234.pdf a la carpeta A, lo que dejaría la subcarpeta A vacía. Lo ideal sería poder hacer esto usando solo el teclado. Puntos de bonificación: una tecla de acceso rápido para volver a seleccionar la última subcarpeta seleccionada (para poder eliminarla, cambiarle el nombre, etc.).

- Folder A
   - Subfolder A
      -File 1234.pdf 
- Folder B

Answer 1

Pido disculpas por la demora en comunicarme con usted con mi respuesta. Ha sido más desafiante de lo que había previsto.

Pero es posible lograr lo que deseas creando unservicioenautomatizador, al que luego se podrá acceder mediante un método abreviado de teclado (tecla de acceso rápido).

tendrás que seguiresta guía sobre cómo crear un servicio para todo el sistema.

---

Comience creando un nuevo servicio enautomatizador. Será necesario recibirarchivos o carpetascomo entrada y estar disponible enDescubridor.

Agrega unEjecute AppleScriptacción al flujo de trabajo. En el área de texto de esa acción, se puede copiar y pegar el siguiente AppleScript:

    use Finder : application "Finder"

    property F_ : missing value -- The previous folder
    property f : missing value -- The files that we moved
    property home : Finder's home as alias


    on run {f, _}
      get its ParentFolderOf:(some item in f)
      set there to the result -- The destination folder, one level up

      -- We won't navigate any higher up the folder tree than
      -- the home folder
      if (its ParentFolderOf:home) is in there then return

      -- Also don't apply this service to other folders that aren't
      -- in the same branch of the folder tree as the home folder
      if (there as text) does not begin with (home as text) then return

      -- The folder we're currently at
      tell Finder to set F_ to ¬
        (the container of some item in f) as alias

      -- Check to ensure there are no files in the destination folder
      -- that risk being overwritten.  If there are, we won't move
      -- the files who share the same name, i.e. only move those that 
      -- are safe to move.
      tell Finder to ¬
        repeat with _g in f
          get name of _g
          set g to [there as text, result] as text
          if not (g exists) then set end of f to _g
          set f to the rest of f
        end repeat

      -- Move the files
      tell Finder ¬
        to set f ¬
        to (move f to there) ¬
        as list as alias list

      -- Reveal them
      reveal f
      activate Finder
    end run


    to ParentFolderOf:(f as alias)
      local f

      set F_ to [f, "::"] as text as alias

      if (f as text) ends with ":" then return F_

      return its ParentFolderOf:F_
    end ParentFolderOf:

Guarda el servicio como quieras. automatizadorlo guarda automáticamente en la ubicación correcta (~/Biblioteca/Servicios). Guardé el mío como"Ascender en el Finder".

A continuación, debes crear un atajo de teclado. Esto se hace a través dePreferencias del Sistema:

Debajo de la lista de servicios, deberá desplazarse hacia abajo hasta la sección marcadaArchivos y carpetas, debajo del cual debería aparecer el nombre de su servicio. Puedes ver el mío resaltado. Creé el acceso directo ⌃▲para el mío (Ctrl+Arriba).

Ahora, cada vez que selecciono archivos y/o carpetas enDescubridory presione ⌃▲, esos archivos y carpetas ascienden un nivel en la jerarquía hasta su carpeta principal. Si quiero moverlos hacia atrás, puedo presionar ⌘Zpara deshacer el movimiento.

Puse una protección para que los archivos y carpetas no se movieran más arriba en el árbol de carpetas que su carpeta de inicio. De todos modos, es poco probable que lo necesites.

Answer 2

Si trabaja en la vista de columnas, puede navegar solo con las teclas de flecha.

Para su ejemplo, suponiendo que comience con el archivo seleccionado...

• Cmd ⌘ C copiar

• Flecha izquierda [esto seleccionará la subcarpeta A], así que para obtener puntos de bonificación...

  • Enter ⌅ le permitirá cambiarle el nombre o Cmd ⌘ Backspace ⌫ eliminarlo
    [Esto no perderá su archivo actualmente en el búfer de copia]

• Flecha izquierda [esto seleccionará la carpeta A]*

• Cmd ⌘ Opt ⌥ V para mover

Esta es la estructura tal como aparece al principio.

y nuevamente al final [después de haber eliminado la Subcarpeta A al pasar]

*Debido a que no se menciona en ninguna parte de la respuesta, en este punto la flecha hacia abajo seleccionaría la carpeta B