¿Cómo puedo filtrar mi tabla de una hoja a otra hoja usando una fórmula? sin una fórmula, puedo simplemente copiar una referencia de las celdas así:
=INDEX(MainSheet!A:A,ROW())
Y luego marque el rango como una tabla, luego filtrelo por columna y luego oculte la columna para facilitar la lectura. No me parece una solución. Quiero lograr eso sin ocultar columnas/filas en la hoja filtrada.
Por ejemplo, digamos que tengo 3 hojas:
- Hoja principal
- Hoja 2
- Hoja 3
En mi hoja "Hoja principal", tengo:
| ID | Name | Filter To
|-------------------------------
| 1 | Record 1 | Sheet 2
| 2 | Record 2 | Sheet 3
| 3 | Record 3 | Sheet 2
| 4 | Record 4 | Sheet 2
| 5 | Record 5 | Sheet 3
Lo que quiero hacer a continuación es tomar estas celdas, filtrarlas por fórmula y luego colocar las filas filtradas en las hojas deseadas ("Hoja 2" y "Hoja 3").
Respuesta1
ConHoja principalcomo:
EnHoja 2, celúlaA1ingresar:
=MATCH("Sheet 2",'Main Sheet'!C:C,0)
y enA2ingresar:
=IFERROR(MATCH("Sheet 2",INDEX('Main Sheet'!C:C,A1+1):INDEX('Main Sheet'!C:C,9999),0)+A1,"")
CopiarA2hacia abajo. EnHoja 2celúlaB1ingresar:
=INDEX('Main Sheet'!A:A,$A1)
y copie esto tanto hacia abajo como a lo ancho.
columna de notasAidentifica la fila desde la que se filtran los datos, columnasByCson losIdentificaciónyNombrede esa fila.
Respuesta2
Escriba la siguiente fórmula en la Hoja 2:
En la celda E242, escriba esta fórmula de matriz, finalice con Ctrl+Shift+Enter y luego rellénela:
{=IFERROR(INDEX(MainSheet!$A$242:$A$246,MATCH(0,IF($F$240=MainSheet!$C$242:$C$246,COUNTIF($E$241:$E241,MainSheet!$A$242:$A$246),""),0)),"")}
En la celda F242 escriba esta fórmula matricial, finalice con Ctrl+Shift+Enter y luego rellénela:
{=IFERROR(INDEX(MainSheet$B$242:$B$246, MATCH(0, IF($F$240=MainSheet!$C$242:$C$246, COUNTIF($F$241:$F241, MainSheet!$B$242:$B$246), ""), 0)),"")}
Escriba la siguiente fórmula en la Hoja 3:
En la celda G242, escriba esta fórmula de matriz, finalice con Ctrl+Shift+Enter y luego rellénela:
{=IFERROR(INDEX(MainSheet!$A$242:$A$246,MATCH(0,IF($H$240=MainSheet!$C$242:$C$246,COUNTIF($G$241:$G241,MainSheet!$A$242:$A$246),""),0)),"")}
En la celda H242, escriba esta fórmula de matriz, finalice con Ctrl+Shift+Enter y luego rellénela:
{=IFERROR(INDEX(MainSheet!$B$242:$B$246, MATCH(0, IF($H$240=MainSheet!$C$242:$C$246, COUNTIF($H$241:$H241, MainSheet!$B$242:$B$246), ""), 0)),"")}
NÓTESE BIEN Ajuste la dirección de la celda en la fórmula según sus necesidades.