☰

Código de macro/VBA para enumerar e imprimir nombres y códigos de todas las macros en un libro de trabajo

tag-icon • tag-icon microsoft-excel vba microsoft-excel-2007
Código de macro/VBA para enumerar e imprimir nombres y códigos de todas las macros en un libro de trabajo

Estoy usando Excel 2007. Para esta pregunta, el nombre de mi libro es PrintCode.xlsm.

¿Existe una macro o un código VBA que imprima todos los nombres y códigos de las macros dentro del libro abierto?

He encontrado algunos ejemplos en la web pero ninguno parece funcionar.

Respuesta1

He encontrado este, mira que es lo que necesitas:Cómo recuperar los nombres de macros de un libro de Excel usando Visual Basic 6.0:

Defina un procedimiento de controlador de eventos de clic para el botón. Utilice el siguiente código para este procedimiento, para mostrar información sobre las macros definidas en C:\Abc.xls:

Private Sub Command1_Click()
    ' Declare variables to access the Excel workbook.
    Dim objXLApp As Excel.Application
    Dim objXLWorkbooks As Excel.Workbooks
    Dim objXLABC As Excel.Workbook

    ' Declare variables to access the macros in the workbook.
    Dim objProject As VBIDE.VBProject
    Dim objComponent As VBIDE.VBComponent
    Dim objCode As VBIDE.CodeModule

    ' Declare other miscellaneous variables.
    Dim iLine As Integer
    Dim sProcName As String
    Dim pk As vbext_ProcKind

    ' Open Excel, and open the workbook.
    Set objXLApp = New Excel.Application
    Set objXLWorkbooks = objXLApp.Workbooks    
    Set objXLABC = objXLWorkbooks.Open("C:\ABC.XLS")

    ' Empty the list box.
    List1.Clear

    ' Get the project details in the workbook.
    Set objProject = objXLABC.VBProject

    ' Iterate through each component in the project.
    For Each objComponent In objProject.VBComponents

        ' Find the code module for the project.
        Set objCode = objComponent.CodeModule

        ' Scan through the code module, looking for procedures.
        iLine = 1
        Do While iLine < objCode.CountOfLines
            sProcName = objCode.ProcOfLine(iLine, pk)
            If sProcName <> "" Then
                ' Found a procedure. Display its details, and then skip 
                ' to the end of the procedure.
                List1.AddItem objComponent.Name & vbTab & sProcName
                iLine = iLine + objCode.ProcCountLines(sProcName, pk)
            Else
                ' This line has no procedure, so go to the next line.
                iLine = iLine + 1
            End If
        Loop
        Set objCode = Nothing
        Set objComponent = Nothing
    Next

    Set objProject = Nothing

    ' Clean up and exit.
    objXLABC.Close
    objXLApp.Quit
End Sub

información relacionada