Agregar unidades al panel de navegación del explorador de archivos de Windows

Question

Quiero mostrar las unidades C: y D: de la misma manera que se muestra "Esta PC" en el panel de navegación. Sé el proceso que debo seguir (veresta respuesta), sin embargo, no sé qué ubicación de registro se supone que debo editar. ¿Alguien puede señalarme? Si es posible, también me gustaría agregar una carpeta específica dentro de D: al panel de navegación.

he probado elsoluciónproporcionado por tenforums, sin embargo, esto no pudo agregar las unidades.

Answer 1

Gracias aSimón Mourierysu respuesta aAnclar una carpeta al Panel de navegación en el Explorador de Windows:

PinDiskD.bat. Ejecute para fijar el disco D:\en algún lugar encima del This PCen elExplorador de archivospanel de navegación. Ejecute con cualquier parámetro que no esté vacío para eliminar el disco D:\del panel, por ejemplo PinDiskD.bat x(tenga en cuenta la :deleAlletiqueta a continuación).

@ECHO OFF
SETLOCAL EnableExtensions
set "_icon=%%SystemRoot%%\system32\imageres.dll,27"
set "_name=d DataDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000d"
set "_target=d:\\"

set "_regK=HKCU\Software\Classes\CLSID"
set "_regE=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer"
if NOT "%~1"=="" goto :deleAll
reg add %_regK%\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regK%\{%_guid%}\DefaultIcon /ve /t REG_EXPAND_SZ /d %_icon% /f
reg add %_regK%\{%_guid%} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0x1 /f
reg add %_regK%\{%_guid%} /v SortOrderIndex /t REG_DWORD /d 0x42 /f
reg add %_regK%\{%_guid%}\InProcServer32 /ve /t REG_EXPAND_SZ /d %%systemroot%%\system32\shell32.dll /f
reg add %_regK%\{%_guid%}\Instance /v CLSID /t REG_SZ /d {0E5AAE11-A475-4c5b-AB00-C66DE400274E} /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v Attributes /t REG_DWORD /d 0x11 /f
reg add %_regK%\{%_guid%}\Instance\InitPropertyBag /v TargetFolderPath /t REG_EXPAND_SZ /d "%_target%" /f
reg add %_regK%\{%_guid%}\ShellFolder /v FolderValueFlags /t REG_DWORD /d 0x28 /f
reg add %_regK%\{%_guid%}\ShellFolder /v Attributes /t REG_DWORD /d 0xF080004D /f
reg add %_regE%\Desktop\NameSpace\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /t REG_DWORD /d 0x1 /f

:endlocal
ENDLOCAL
goto :eof

:deleAll
reg delete %_regK%\{%_guid%}                                   /f
reg delete %_regE%\Desktop\NameSpace\{%_guid%}                 /f
reg delete %_regE%\HideDesktopIcons\NewStartPanel /v {%_guid%} /f
goto :endlocal

PinDiskC.bat. Fija el disco C:\en el panel. Lo mismo quePinDiskD.batexcepto cuatro setcomandos principales:

set "_icon=%%SystemRoot%%\system32\imageres.dll,31"
set "_name=c SystemDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000c"
set "_target=c:\\"
…

D:\bat\PinCodePages.bat. Ancla una carpeta local particular al panel. Lo mismo quePinDiskD.batexcepto cuatro setcomandos principales (verifique dos veces la validez de las variables, _icony ) :_name_guid_target

set "_icon=%%SystemRoot%%\system32\shell32.dll,176" # any valid icon
set "_name=My Folder"                               # any valid name
set "_guid=ffffffff-ffff-ffff-0000-00000000c0de"    # a valid GUID (no braces)
set "_target=d:\Utils\CodePages\\"                  # any valid local path
…

Ejemplo de cómo se ve en Windows 10 después de ejecutar todos los scripts anteriores: