☰

Si ingreso las letras TL en la celda A8, ¿hay alguna manera de convertir esa celda y muchas otras en esa fila en azul?

tag-icon • tag-icon microsoft-excel microsoft-excel-2013
Si ingreso las letras TL en la celda A8, ¿hay alguna manera de convertir esa celda y muchas otras en esa fila en azul?

Si ingreso las letras TL en la celda A8, ¿hay alguna manera de convertir esa celda y muchas otras en esa fila en azul? ¿Hay alguna manera de tener múltiples variaciones de letras/colores?

Tengo 8 combinaciones de dos letras que corresponden a 8 colores. Por ejemplo: TS=azul claro TC=azul medio TL=azul oscuro DD=negro RS=verde claro RC=verde medio RL=verde oscuro LT=marrón Me gustaría ingresar una de estas combinaciones de letras en M8 y tener columnas , B,C,E,F,K-AM en la fila 8 gira el color correspondiente. ¿Hay una manera de hacer eso?

Respuesta1

Si ingreso las letras TL en la celdaA8... ingrese una de estas combinaciones de letras enM8& tiene columnas, B,C,E,F,K-AM en la fila 8...

Tu narrativa es confusa. Este código es para M8.

Ajuste el nombre de la hoja de trabajo y los parámetros RGB para los colores que desee y luego ejecute este código.

Option Explicit

Sub addCFRs()

    Dim i As Long, rng As Range, arr1 As Variant, arr2 As Variant

    arr1 = Array("TS", "TC", "TL", "DD", "RS", "RC", "RL", "LT")
    arr2 = Array(RGB(0, 0, 255), RGB(0, 0, 128), RGB(0, 0, 64), RGB(0, 0, 0), _
                 RGB(0, 255, 0), RGB(0, 128, 0), RGB(0, 64, 0), RGB(0, 0, 0))

    With Worksheets("sheet6")

        Set rng = Intersect(.Range("B:C, E:F, K:AM"), .Range("8:8"))

        With rng

            .FormatConditions.Delete

            For i = LBound(arr1) To UBound(arr1)

                .FormatConditions.Add Type:=xlExpression, Formula1:="=$M8=" & Chr(34) & arr1(i) & Chr(34)
                .FormatConditions(.FormatConditions.Count).Interior.Color = arr2(i)

            Next i

        End With

    End With

End Sub

La mayoría de los RGB se acercan un poco a lo que desea, excepto el marrón; No tengo idea de qué hace que el RGB sea marrón.

Respuesta2

Esto se puede hacer usando formato condicional.
Necesitará una fórmula separada para cada color.

  • Resalte las celdas que desea cambiar de color en la fila 8 (puede usar Ctrl+ clic para seleccionar celdas separadas)
  • Vaya a "Formato condicional" y seleccione "Nueva regla".
  • Seleccione "Usar una fórmula para determinar qué celdas formatear"
  • En el tipo de descripción de la regla=$M8="TL"
  • Haga clic en "Formato" y elija la pestaña "Rellenar" en la parte superior
  • Seleccione el color correcto para el código
  • Haga clic en Aceptar y luego en Aceptar nuevamente.
    Todo listo para la fila 8.

Si desea que haga más filas, vaya a "Formato condicional" y seleccione "Administrar reglas".

Seleccione el ícono a la derecha del cuadro "Se aplica a" y luego resalte todas las áreas que desea cambiar de color. Nuevamente, puede utilizar Ctrlpara seleccionar áreas separadas. Puede seleccionar columnas enteras si lo desea, pero esto puede ralentizar la hoja.

Una vez que haya configurado esto, puede repetir el proceso para los otros códigos de color, simplemente reemplácelo TLen la fórmula con el código que desea usar.

información relacionada