Estoy intentando omitir una fila específica en una matriz, no el valor.
Por ejemplo, supongamos que estamos en la columna A:
0
3
0 <--- Row 3
0
¿Cómo puedo omitir la tercera fila en A1:A4, de modo que pequeño (A1:A4, 2) pueda ser igual a 0 y pequeño (A1:A4, 3) sea igual a 3?
Me gustaría omitir una fila específica, no el valor. No puedo cambiar las filas, necesito una fórmula que ignore una fila específica en una matriz
¡Gracias por la ayuda!
Respuesta1
Otro enfoque es con la INDEXfunción que crea una matriz de las filas que desea conservar (y hay muchas formas de crear esta matriz). En su ejemplo específico, usando AGGREGATEen lugar de SMALL:
=AGGREGATE(15,4,INDEX($A$1:$A$4,IF(1,N({1,2,4}))),2)
Si sólo tiene cuatro filas y quiere ignorar sólo una, el enfoque realmente no importa. Si sus rangos son más grandes y su selección de filas para ignorar es más compleja (y más de una), crear una matriz de números de fila para retener puede ser más sencillo.
Respuesta2
Si vas a sumar los números usa SUMPRODUCT:
=SUMPRODUCT((ROW(A1:A4)<>3)*(A1:A4))
Si va a hacer algo más, lo más probable es que necesite una fórmula ingresada en una matriz con IF dentro:
IF(ROW(A1:A4)<>3,A1:A4)
Esto hará que la fórmula sea una fórmula matricial que debe confirmarse con Ctrl-Shift-enter en lugar de Enter al salir del modo de edición.
Entonces, por ejemplo, si quisiéramos el MAX:
=MAX(IF(ROW(A1:A4)<>3,A1:A4))
Ingresado con Ctrl-Shift-Enter.
Para los pequeños:
=SMALL(IF(ROW(A1:A4)<>3,A1:A4),3)
Ingresado con Ctrl-Shift-Enter 3no devolvería0
Otra forma de AGREGADO que es igual a la pequeña de arriba:
=AGGREGATE(15,7,A1:A4/(ROW(A1:A4)<>3),3)
Respuesta3
Para omitir la tercera fila especificada en A1:A4
Intente ingresar esta fórmula normal:
=SMALL(IF({1;1;0;1},A1:A4),3)
devolverá el resultado3
y,
=SMALL(IF({1;1;0;1},A1:A4),2)
devolverá el resultado0