Convertir de texto a fecha en Excel

Question

Necesito su ayuda para convertir el texto - "Precio PARA EL PERIODO DEL 01/08/21 AL 15/01/21" hasta la fecha 15/01/2021.

Estoy usando la fórmula =DATE(RIGHT(TRIM(RIGHT(SUBSTITUTE(TRIM(Edited!A2)," ",REPT(" ",100)),100))&"20",4),MID(TRIM(RIGHT(SUBSTITUTE(TRIM(Edited!A2)," ",REPT(" ",100)),100))&"20",4,2),LEFT(TRIM(RIGHT(SUBSTITUTE(TRIM(Edited!A2)," ",REPT(" ",100)),100))&"20",2))pero el resultado que obtengo es 15/01/2120 en lugar de 15/01/2021.

¿Alguien puede ayudar con lo anterior?

Answer 1

Debido a que su cadena termina con una fecha de 8 caracteres seguida de un espacio, podemos usar:

=LEFT(RIGHT(TRIM(Edited!A2),8),6) & RIGHT(RIGHT(TRIM(Edited!A2),8),2)+2000

Nota:

Esto aísla la fecha y convierte el año de 2 dígitos en un año de 4 dígitos.
Esto puede acortarse si está utilizandoexcel 365.
El resultado es una cadena y no una verdadera fecha de Excel.

EDITAR #1:

Para poner el mes primero:

=MID(RIGHT(TRIM(Edited!A2),8),4,3) & LEFT(RIGHT(TRIM(Edited!A2),8),3) & RIGHT(RIGHT(TRIM(Edited!A2),8),2)+2000

EDITAR #2:

Si utilizaexcel 365, luego haces una cita real en Excel con:

=LET(d,RIGHT(TRIM(Edited!A2),8)    ,DATE(RIGHT(d,2)+2000,MID(d,4,2),LEFT(d,2)))

Answer 2

¿Este sencillo te funciona?

=DATEVALUE(TRIM(RIGHT(SUBSTITUTE(TRIM(Edited!A2)," ",REPT(" ",100)),100)))

Como dijiste,
=TRIM(RIGHT(SUBSTITUTE(TRIM(Edited!A2)," ",REPT(" ",100)),100))obtiene la última cadena de la oración
y luego =DATEVALUE()convierte la cadena en datos de fecha y hora y el resultado depende de la configuración regional de tu computadora.
Además, debe configurar el formato de la columna como fecha y hora y personalizarlo fácilmente ( mm/dd/yyyyo dd/mm/yyyyetc.).

Si conoce la longitud de la cadena de fecha al final y es de longitud fija, será más simple: =DATEVALUE(RIGHT(TRIM(Edited!A2),8))