☰

Outlook VBA: abra el archivo adjunto del correo electrónico en la cita y extraiga la dirección de correo electrónico del remitente

tag-icon • tag-icon microsoft-outlook vba extract attachments
Outlook VBA: abra el archivo adjunto del correo electrónico en la cita y extraiga la dirección de correo electrónico del remitente

Tengo más de 200 entradas de calendario (citas) y todas contienen el mensaje de correo electrónico original como archivo adjunto. Necesito extraer la dirección de correo electrónico del remitente del archivo adjunto del correo electrónico en la cita.

Sé cómo extraer la dirección de correo electrónico del remitente de un objeto MailItem ( MailItem.SenderEmailAddress), pero no sé cómo acceder a estas propiedades cuando el mensaje de correo electrónico ahora es un archivo adjunto en una cita. El AppointmentItemobjeto tiene una propiedad Adjuntos, pero no hay otra información disponible sobre cómo acceder a las propiedades en el objeto Adjuntos. Probé AppointmentItem.Attachments.item(1).SenderEmailAddress y obtuve 'objeto no compatible...'

Respuesta1

Puede guardar el archivo adjunto .msg, abrirlo como elemento de correo y luego leer la propiedad del elemento de correo.

Option Explicit ' Consider this mandatory
' Tools | Options | Editor tab
' Require Variable Declaration
' If desperate declare as Variant


Private Sub saveAndRetrievePropertyOfAttachedMail()

    Dim sPath As String
    
    ' the selected item may not be an AppointmentItem
    Dim oItem As Object
    
    sPath = ""
    
    Set oItem = ActiveExplorer.Selection.Item(1)
    
    If TypeName(oItem) = "AppointmentItem" Then
        Debug.Print oItem.subject
        
        ' sPath is initially blank
        ' There are risks with public variables.
        ' This is a slightly awkward way to avoid declaring sPath as a public variable
        saveAttachmentsToDriveFolder oItem, sPath
        
        returnPropertiesOfAttachmentInDriveFolder sPath
        
    End If
    
End Sub


Sub saveAttachmentsToDriveFolder(objItem, strPath)

    Dim fso As Object
    Dim fldTemp As Object
    
    Dim objAtt As Object
    Dim strFile As String
    
    Set fso = CreateObject("Scripting.FileSystemObject")
    
    ' This is a default folder everyone should have.
    ' You may use another folder.
    ' Kill the files when you are done or delete manually
    Set fldTemp = fso.GetSpecialFolder(2) ' TemporaryFolder
    Debug.Print fldTemp
    
    strPath = fldTemp.Path & "\"
    Debug.Print strPath
    
    For Each objAtt In objItem.Attachments
        strFile = strPath & objAtt.FileName
        Debug.Print strFile
        objAtt.SaveAsFile strFile
    Next
    
End Sub


Sub returnPropertiesOfAttachmentInDriveFolder(strAttachmentFolder)

Dim objFileSystem As Object
Dim objFolder As Object
Dim objFiles As Object
Dim objFile As Object
Dim objItem As Object

Set objFileSystem = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFileSystem.GetFolder(strAttachmentFolder)
Set objFiles = objFolder.Files

For Each objFile In objFiles

    If objFileSystem.GetExtensionName(objFile) = "msg" Then
    
        'Open msg file
        Set objItem = Session.OpenSharedItem(objFile.Path)
        Debug.Print objItem.SenderEmailAddress

    End If
Next

End Sub

información relacionada