☰

Procesamiento por lotes: ¿Cómo convertir muchos nombres de archivos en código HTML?

tag-icon • tag-icon windows batch pdf
Procesamiento por lotes: ¿Cómo convertir muchos nombres de archivos en código HTML?

Tengo una carpeta con archivos PDF con nombres como

page_1_excercise_2.pdf
page_23_excercise_3_4_and_5.pdf
page_456_excercise_16_and_17.pdf

Los números pueden contener 1, 2 o 3 dígitos. Necesito generar código HTML como:

<a href="pdfs/page_1_excercise_2.pdf">Page 1, Excercise 2</a>
<a href="pdfs/page_23_excercise_3_4_and_5.pdf">Page 23, Excercise 3, 4 and 5</a>
<a href="pdfs/page_456_excercise_16_and_17.pdf">Page 456, Excercise 16 and 17</a>

¿Hay alguna manera de hacerlo usando un archivo por lotes en Windows?

Esto es lo que pude encontrar hasta ahora:

@echo off
Setlocal EnableDelayedExpansion

for /f "tokens=*" %%i in ('dir /b /a:-d *.pdf') do (
set filename=%%i
set filename=!filename:.pdf=!
set filename=!filename:_= !
echo ^<a href="pdfs/%%i"^>!filename!^</a^> >> files.html)

Funciona bien, pero me gustaría agregar una coma después de cada número de ejercicio y convertir la primera letra (como "P" en la "Página 456...") a mayúscula.

Respuesta1

@echo off && setlocal enableextensions enabledelayedexpansion

cd /d "%~dp0" && for %%i in ("%cd%")do set "_dir=%%~nxi"
set "_alf=A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z"

>.\Output.html (
    findstr /be ^<.*^> "%~f0"
    for /f tokens^=1-7*delims^=_ %%i in ('where .:*.pdf')do (
         call %:^) "%%~ni" "%%~k" _str_1 _str_2 "%_alf%" && if "%%~xl" == ".pdf" (
         echo;^<a href="%_dir%/%%~ni_%%~j_%%~k_%%~nxl"^>!_str_1! %%~j, !_str_2! %%~nl^</a^>
        )else if "%%~xn" == ".pdf" (
         echo;^<a href="%_dir%/%%~ni_%%~j_%%~k_%%~l_%%~m_%%~nxn"^>!_str_1! %%~j, !_str_2! %%~l %%~m %%~nn^</a^>
        )else if "%%~xo" == ".pdf" (
         echo;^<a href="%_dir%/%%~ni_%%~j_%%~k_%%~l_%%~m_%%~n_%%~nxo"^>!_str_1! %%~j, !_str_2! %%~l, %%~m %%~n %%~no^</a^>
        )
    ) 
    echo\^</body^>&echo\^</html^>) & endlocal & goto :eof

%:^)
set "_str#1=%~1" && set "_str#2=%~2" && for %%i in (%~5)do (
     if /i "!_str#1:~0,1!" == "%%~i" set "%~3=%%~i!_str#1:~1!"
     if /i "!_str#2:~0,1!" == "%%~i" set "%~4=%%~i!_str#2:~1!"
    )

exit /b

<!doctype html>
<html>
<head>
<title>Our Funky HTML Page</title>
<meta name="description" content="Our first page">
<meta name="keywords" content="html tutorial template">
</head>
<body>
  • Salida del archivo HTML:
<!doctype html>
<html>
<head>
<title>Our Funky HTML Page</title>
<meta name="description" content="Our first page">
<meta name="keywords" content="html tutorial template">
</head>
<body>
<a href="Q1728787/page_1_excercise_2.pdf">Page 1, Excercise 2</a>
<a href="Q1728787/page_23_excercise_3_4_and_5.pdf">Page 23, Excercise 3, 4 and 5</a>
<a href="Q1728787/page_456_excercise_16_and_17.pdf">Page 456, Excercise 16 and 17</a>
</body>
</html>

1.Ingresa a la carpeta donde tienes los archivos pdf, o ejecuta bat en esa misma carpeta:

cd /d "%~dp0" 
:: or 
cd /d "D:\Full\Path\To\Your\PDFs\Folder"

2.Obtenga solo el nombre de la carpeta actual y guárdelo en la variable:

for %%i in ("%cd%")do set "_dir=%%~nxi"

3.Define una variable con letras mayúsculas para configurarla utilizada en un forbucle delimitado por coma:

set "_alf=A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z"

4.Bloque de procesamiento de cadena de redirección en archivo html:

>.\Output.html (
        ...
        ...
       )

5.Agregue las etiquetas html necesarias al comienzo de cada línea y después de la última línea de su bat y use a findstr /Begin /End <one or more characters>para filtrarlas en su archivo html:

...

findstr /be ^<.*^> "%~f0"

...

<!doctype html>
<html>
<head>
<title>Our Funky HTML Page</title>
<meta name="description" content="Our first page">
<meta name="keywords" content="html tutorial template">
</head>
<body>

6.Utilice un for /fbucle como comando que enumere solo los archivos de su carpeta y asuma como delimitador _, temido por tokensdel 1 al 8 1-7*:

  for /f tokens^=1-7*delims^=_ %%i in ('where .:*.pdf')do ...

7.Utilice un ifpara comparar las acciones realizadas para cada token posible donde tenga su extensión de archivo, que coincidirá con la composición de la cadena con o sin coma:

....)do ...  && if "%%~xl" == ".pdf" (
          echo  ...
        )else if "%%~xn" == ".pdf" (
          echo  ...
        )else if "%%~xo" == ".pdf" (
          echo  ...
        )

8.Para todos los casos en los que la extensión es igual a .pdf, trate las cadenas dentro de una función para reemplazar el primer carácter en mayúscula y ya tomando sus tokens y sus nombres para cada variable donde guardará las cadenas para componer el resultado deseado:

...)do call %:^) "%%~ni" "%%~k" _str_1 _str_2 "%_alf%" && if ... (
         echo;^<a href="%_dir%/%%~ni_%%~j_%%~k_%%~nxl"^>!_str_1! %%~j, !_str_2! %%~nl^</a^>
        )else if ... (
         echo;^<a href="%_dir%/%%~ni_%%~j_%%~k_%%~l_%%~m_%%~nxn"^>!_str_1! %%~j, !_str_2! %%~l %%~m %%~nn^</a^>
        )else if ... (
         echo;^<a href="%_dir%/%%~ni_%%~j_%%~k_%%~l_%%~m_%%~n_%%~nxo"^>!_str_1! %%~j, !_str_2! %%~l, %%~m %%~n %%~no^</a^>
        )

9.Lleve su cadena hacia pagey excercisehacia una función, junto con la variable del alfabeto _alfen mayúscula, donde en el bucle el reemplazo del primer carácter que coincida con el caso insesitivo en el uso de if /iejecutará la subcadena con reemplazar:


...)do call %:^) "%%~ni" "%%~k" _str_1 _str_2 "%_alf%" ... (
     ....
     )

%:^)
set "_str#1=%~1" && set "_str#2=%~2" && for %%i in (%~5)do (
     if /i "!_str#1:~0,1!" == "%%~i" set "%~3=%%~i!_str#1:~1!"
     if /i "!_str#2:~0,1!" == "%%~i" set "%~4=%%~i!_str#2:~1!"
    )
...

Recursos adicionales:

información relacionada