☰

¿Cómo autocompletar una fórmula para omitir una fila?

tag-icon • tag-icon microsoft-excel worksheet-function auto-form-fill
¿Cómo autocompletar una fórmula para omitir una fila?

Estoy intentando arrastrar datos de una hoja maestra de Excel a otro archivo de Excel, pero los números se omiten por fila.

Esto es lo que estoy tratando de hacer

='[MASTER ITEM LIST 2024.xlsx]'!$E15+'[MASTER ITEM LIST 2024.xlsx]'!$E16

='[MASTER ITEM LIST 2024.xlsx]'!$E17+'[MASTER ITEM LIST 2024.xlsx]'!$E18

='[MASTER ITEM LIST 2024.xlsx]'!$E19+'[MASTER ITEM LIST 2024.xlsx]'!$E21

Lo siguiente ocurre durante el autocompletar.

='[MASTER ITEM LIST 2024.xlsx]'!$E15+'[MASTER ITEM LIST 2024.xlsx]'!$E16

='[MASTER ITEM LIST 2024.xlsx]'!$E16+'[MASTER ITEM LIST 2024.xlsx]'!$E17

='[MASTER ITEM LIST 2024.xlsx]'!$E17+'[MASTER ITEM LIST 2024.xlsx]'!$E18

También intenté duplicar las líneas y hacer que reconociera el patrón de salto, pero esto es lo que obtengo.

='[MASTER ITEM LIST 2024.xlsx]'!$E15+'[MASTER ITEM LIST 2024.xlsx]'!$E16

='[MASTER ITEM LIST 2024.xlsx]'!$E17+'[MASTER ITEM LIST 2024.xlsx]'!$E18

='[MASTER ITEM LIST 2024.xlsx]'!$E17+'[MASTER ITEM LIST 2024.xlsx]'!$E18

='[MASTER ITEM LIST 2024.xlsx]'!$E19+'[MASTER ITEM LIST 2024.xlsx]'!$E21

='[MASTER ITEM LIST 2024.xlsx]'!$E19+'[MASTER ITEM LIST 2024.xlsx]'!$E21

='[MASTER ITEM LIST 2024.xlsx]'!$E21+'[MASTER ITEM LIST 2024.xlsx]'!$E23

Respuesta1

Aquí hay una forma de resolver usando INDIRECT()la función:

ingrese la descripción de la imagen aquí

• Fórmula utilizada en la celdaA1

=INDIRECT("'[MASTER ITEM LIST 2024.xlsx]Sheet1'!$E"&(ROW()*2-1)+14)+
 INDIRECT("'[MASTER ITEM LIST 2024.xlsx]Sheet1'!$E"&ROW()*2+14)

O, un poco más corto:

=SUM(INDIRECT("'[MASTER ITEM LIST 2024.xlsx]Sheet1'!$E"&(ROW()*2+{-1,0})+14))

Nota:La fórmula anterior devolverá un error --> #REF!si MASTER ITEM LIST 2024.xlsxno se abre mientras se trabaja con el archivo donde se ingresa la fórmula. Funciona siempre que ambos archivos estén abiertos.

También un inconveniente más es la función utilizada. INDIRECT()La función es de naturaleza volátil, es decir, siempre se volverá a calcular cuando haya un cambio en cualquier libro abierto, además de ralentizar la funcionalidad de trabajo de Excel, ya que es de un solo subproceso. El segundo método INDIRECT()requerirá presionar CTRL+ SHIFT+ ENTERal salir del modo de edición, según la versión.

Una alternativa es usar TOCOL()+ WRAPROWS()con BYROW()función.

ingrese la descripción de la imagen aquí

• Fórmula utilizada en la celdaA1

=LET(
     x, TOCOL('[MASTER ITEM LIST 2024.xlsx]Sheet1'!$E:$E,1),
     y, ROWS(x),
     BYROW(WRAPROWS(IF(ISEVEN(y),x,VSTACK(x,0)),2),SUM))

La fórmula anterior compartida funciona con Office Insiderspero para que funcione es Current Channel Usersnecesario MS365agregar unLAMBDA()

=LET(
     x, TOCOL('[MASTER ITEM LIST 2024.xlsx]Sheet1'!$E:$E,1),
     y, ROWS(x),
     BYROW(WRAPROWS(IF(ISEVEN(y),x,VSTACK(x,0)),2),LAMBDA(a,SUM(a))))

información relacionada