estilos de línea no aplicados en gnuplot (epslatex)

Question

Hola, me gustaría dibujar 2 curvas en un mismo gráfico usando gnuplot (terminal epslatex). Estoy usando un script gnuplot, que funciona bien, excepto que no aplica colores de línea definidos usando el comando set style line.

Aquí está el guión:

set terminal epslatex color colortext size 9cm,5cm
set size 1,1
set output "lorenzov_faktor.tex"

set xrange [0:10]
set yrange [0:10]

set xtics ("$0c$" 0, "$c$" 10)
set ytics ("$0$" 0, "$1$" 1, "$\\infty$" 10)

set style line 1 lc rgb "#FF0055"
set style line 2 lc rgb "#2C397D"

unset grid

set ylabel "$\\gamma$"
set xlabel "$u$"

set key left top

f(x) = 1/sqrt(1 - (x/10)**2) 
g(x) = 1

set xrange [0:11]
set yrange [0:9]

plot f(x) ls 2 lw 3 lt 1 title "$\\gamma$", g(x) ls 1 lw 1 lt 2 notitle

Produce un gráfico donde los colores no coinciden con mis definiciones de estilos de línea:

Answer 1

Debe eliminar lt 1y lt 2de su secuencia de comandos, porque restauran los tipos de línea predeterminados en lugar de los estilos de línea definidos por el usuario. Alternativamente, puede cambiar el tipo de línea (sólida, discontinua, etc.) sin afectar el color usando ltcuando lo haga set style line.

set style line 1 lc rgb "#FF0055" lt 1
set style line 2 lc rgb "#2C397D" lt 3

...

plot f(x) ls 2 lw 3 title "$\\gamma$", g(x) ls 1 lw 1 notitle