Cómo buscar, reemplazar y agregar un patrón al final de cada línea

Question

Tengo la siguiente lista de artículos:

bigBone
fishMarket
dogCollar
...

Necesito generar un mapeo de dos caracteres como este:

bigBone -> bb
fishMarket -> fm
dogCollar -> dc
...

¿Cómo puedo crear el mapeo anterior usando sed?

He probado algo como:

sed -i -r 's/^([a-z]{1})[a-z]+([A-Z]{1})[a-zA-Z]+/ -> \1\L\2/' file

Yo viesta pregunta, pero no estoy seguro de cómo incorporar el concepto aquí. Gracias.

Answer 1

Si te entiendo correctamente, entonces querrás conservar toda la línea y simplemente agregar algo:

sed -r 's/^([a-z]{1})([a-z]+)([A-Z]{1})([a-zA-Z]+)$/\1\2\3\4 -> \1\L\3/' file

editar:

devnull tuvo que recordarme que hay una solución fácil para esto:

sed -r 's/^([a-z]{1})[a-z]+([A-Z]{1})[a-zA-Z]+/& -> \1\L\2/' file

O un poco más elegante (que mi primer intento):

sed -r '
h
s/^([a-z]{1})[a-z]+([A-Z]{1})[a-zA-Z]+/ -> \1\L\2/
t append
b
: append
H
g
s/\n//' file

Answer 2

Usando GNU sed:

sed -r 's/(.)[^[:upper:]]*(.).*/& -> \1\L\2/' inputfile

Para su aporte, produciría:

bigBone -> bb
fishMarket -> fm
dogCollar -> dc

Answer 3

Para generalizar a fooBarBaz -> fbb, abCdEfGh -> aceg, con GNU sed:

sed -r 's/(.)(.*)/\1\n\2 -> \L\1/;:1
        s/\n([^[:upper:]]*([[:upper:]]))(.*)/\1\n\3\L\2/;t1;s/\n//'

POSIX sedno tiene \L. De manera portátil, tendrías que recurrir al uso ye ingresar manualmente todos los caracteres que deseas convertir a minúsculas. Algo como:

LC_ALL=C sed '/^\([[:alpha:]]\).*/{
h;s//\1/;y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/;G
s/\(.\).\(.\)\(.*\)/\2\
\3 -> \1/;:1
/.*\n[^A-Z]*\([A-Z]\).*/{h;s//\1/
y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/;G
s/^\(.\)\n\(.*\)\n\([^A-Z]*[A-Z]\)\(.*\)/\2\3\
\4\1/;t1
}
s/\n//;}'

Answer 4

Esta respuesta es similar a la de @devnull,

$ sed 's/\(.\).*\([A-Z]\).*/& -> \1\L\2/g' file
bigBone -> bb
fishMarket -> fm
dogCollar -> dc