☰

¿Contadores de rendimiento de Server 2003 para recursos compartidos de archivos?

tag-icon • tag-icon windows-server-2003 file-sharing performance-monitoring performance
¿Contadores de rendimiento de Server 2003 para recursos compartidos de archivos?

Tengo un disco con varias cosas diferentes sucediendo. Me gustaría determinar aproximadamente qué parte de la actividad del disco se debe al intercambio de archivos. ¿Existe un contador para esto?

Además, y puede que haya estado soñando con esto, creo recordar haber visto algún programa que podría permitirme monitorear la actividad de los archivos de una carpeta particular dentro de un recurso compartido. ¿Te suena algo? Gracias.

Respuesta1

En referencia al seguimiento de la actividad de una carpeta:

Puede usar WMI (CIM_DataFile) para monitorear una carpeta en busca de modificaciones usando algo similar a esto como consulta:

SELECCIONE * DE __InstanceOperationEvent DENTRO DE 1 DONDE TargetInstance ISA "CIM_DataFile" Y TargetInstance.Drive="C:" Y TargetInstance.Path="\Data"

Algo como esto:

' Full path to the folder to monitor
sPath = "\\localhost\c$\Scripts"
sComputer = split(sPath,"\")(2)
sDrive = split(sPath,"\")(3)
sDrive = REPLACE(sDrive, "$", ":")
sFolders = split(sPath,"$")(1)
sFolders = REPLACE(sFolders, "\", "\\") & "\\"

' Create our WMI instance
Set objWMIService = GetObject("winmgmts:\\" & sComputer & "\root\cimv2")
' Begin monitoring
Set colMonitoredEvents = objWMIService.ExecNotificationQuery _
("SELECT * FROM __InstanceOperationEvent WITHIN 1 WHERE " _
& "TargetInstance ISA 'CIM_DataFile' AND " _
& "TargetInstance.Drive='" & sDrive & "' AND " _
& "TargetInstance.Path='" & sFolders & "'")

Wscript.Echo vbCrlf & Now & vbTab & _
"Begin Monitoring for a Folder Change Event..." & vbCrlf

Do
    Set objLatestEvent = colMonitoredEvents.NextEvent
    Select Case objLatestEvent.Path_.Class

        Case "__InstanceCreationEvent"
            WScript.Echo Now & vbTab & objLatestEvent.TargetInstance.FileName _
            & " was created" & vbCrlf

        Case "__InstanceDeletionEvent"
            WScript.Echo Now & vbTab & objLatestEvent.TargetInstance.FileName _
            & " was deleted" & vbCrlf

        Case "__InstanceOperationEvent"
            If objLatestEvent.TargetInstance.LastModified <> _
                objLatestEvent.PreviousInstance.LastModified then
                WScript.Echo Now & vbTab & objLatestEvent.TargetInstance.FileName _
                & " was modified" & vbCrlf
            End If

        IF objLatestEvent.TargetInstance.LastAccessed <> _
            objLatestEvent.PreviousInstance.LastAccessed then
            WScript.Echo Now & vbTab & objLatestEvent.TargetInstance.FileName _
            & " was accessed" & vbCrlf
        End If

    End Select
Loop

Set objWMIService = nothing
Set colMonitoredEvents = nothing
Set objLatestEvent = nothing

información relacionada