☰

Aplicar la política de firmas en Exchange 2003 utilizando campos de Active Directory

tag-icon • tag-icon active-directory exchange outlook
Aplicar la política de firmas en Exchange 2003 utilizando campos de Active Directory

Nuestra organización ha decidido que necesita tener un bloque de firma estándar para todos los usuarios según su nombre, cargo, detalles de contacto y ubicación de la oficina, todos los cuales se almacenan en Active Directory.

¿Alguien ha encontrado una buena solución para generar automáticamente firmas de Outlook/Exchange 2003 basadas en campos de Active Directory?

Respuesta1

Soy cliente desde hace mucho tiempo y fanático deUtilidades de correo exclamador.

Se encuentra en su servidor Exchange y tiene muchas reglas personalizables que determinan si se aplica estacionario o no. Hago que agregue en la parte superior de todos los correos electrónicos enviados externamente nuestro logotipo corporativo y el nombre de las personas, el cargo y varios números de teléfono en la parte inferior, todo extraído de Active Directory.

Solo utilicé el soporte una vez, pero fueron muy amables, estaban bien informados y resolvieron mi problema muy rápidamente.

Respuesta2

Tuve muy buena suerte con un guión que escribí. Escribe desde varios campos AD en un documento de Word invisible y luego lo copia en Outlook 2007 como firma predeterminada y de respuesta.

Dejé de ejecutarlo automáticamente cada vez que inicie sesión. Muy raramente tendría problemas en el primer inicio de sesión de un usuario en una máquina, donde Outlook aún no podía abrirse sin pasar por el asistente. A partir de ahora es un GPO que simplemente envía un acceso directo a los escritorios de los usuarios llamado "Restablecer firma de correo electrónico". Esto también permite a los usuarios tener firmas no predeterminadas sin que se anulen cada vez.

On Error Resume Next

Set objSysInfo = CreateObject("ADSystemInfo")

strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)

strName = objUser.FullName
strTitle = objUser.Title
strDepartment = objUser.Department
strCompany = objUser.Company
strPhone = objUser.telephoneNumber
strFax = objUser.faxNumber

strStreet = objUser.StreetAddress
strCity = objUser.L
strState = objUser.St
strPOBox = objUser.postalCode

strFirstName = objUser.givenName
strInitials = objUser.initials
strLastName = objUser.sn
If strInitials = "" Then
    strFullName = strFirstName & " " & strLastName
Else
    strFullName = strFirstName & " " & strInitials & ". " & strLastName
End If

Set objWord = CreateObject("Word.Application")

Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
objSelection.Style = "No Spacing" 
objSelection.Font.Name = "Calibri"
objSelection.Font.Size = "11"

Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature

Set objSignatureEntries = objSignatureObject.EmailSignatureEntries

objSelection.TypeParagraph()
objSelection.TypeText "Sincerely,"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText "ORGANIZATION NAME"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strFullName & ", " & strTitle
'objSelection.TypeText strName & ", " & strTitle
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.TypeText strStreet
objSelection.TypeParagraph()
objSelection.TypeText strCity & ", " & strState & " " & strPOBox
objSelection.TypeParagraph()
objSelection.TypeText "Desk: " & strPhone
objSelection.TypeParagraph()
objSelection.TypeText "Fax:    " & strFax
objSelection.TypeParagraph()

'Hyperlink below
objDoc.Hyperlinks.Add objSelection.Range, "www.yoursitename.com", "", "", "www.yoursitename.com", ""

objSelection.TypeParagraph()
objSelection.TypeParagraph()

'Picture below
Set objShape = objSelection.InlineShapes.AddPicture("\\fileserver\path\to\image.BMP")

Set objSelection = objDoc.Range()

objSignatureEntries.Add "AD Signature", objSelection
objSignatureObject.NewMessageSignature = "AD Signature"
objSignatureObject.ReplyMessageSignature = "AD Signature"

objDoc.Saved = True
objWord.Quit

Si tienes alguna pregunta, ¡házmelo saber!

información relacionada