☰

Encuentre procesos con alto consumo de CPU en Azure Log Analytics

tag-icon • tag-icon azure
Encuentre procesos con alto consumo de CPU en Azure Log Analytics

He creado la siguiente alerta en Log Analytics. La alerta está diseñada para llegar a todas las computadoras donde el uso total de CPU superó el 90% en los últimos diez minutos. Sin embargo, cuando ejecuto la alerta aparece el error:

Operador 'unirse': no ​​se pudo resolver la expresión de tabla o columna denominada 'FindCPU'

¿Alguien puede decirme qué podría ser necesario para solucionar este problema?

//Find Top processes utilizing CPU
// by finding the machine(s) using over 90% of CPU
// then finding the processes using the CPU
// also finding CPU count of the machines to find the actual percentage of CPU being used

//defining our CPU threshold
let CPUThreshold = 90;

//define time sample rate
let Time = 10m;

//define Count of processes to return
let Count = 5;

//Find instances of total cpu being used above 90% over the last 10 minutes
let TopCPU = Perf
| where TimeGenerated > now(-Time)
              and ObjectName == "Processor"
              and CounterName == "% Processor Time"
              and InstanceName == "_Total"
              and CounterValue > CPUThreshold
| project Computer, ObjectName
              , CounterName, CounterValue
              , TimeGenerated;
//end query

// find top Processes, excluding _Total and Idle instances, there may be other instances you want to exclude as well
let TopProcess = Perf
| where TimeGenerated > now(-Time)
               and CounterName == "% Processor Time"
               and InstanceName != "_Total"
               and InstanceName != "Idle"
| project Computer, ObjectName
              , CounterName, InstanceName
              , CounterValue, TimeGenerated;
// end query

// find CPU count for servers(s)
let FindCPU = Perf
| where TimeGenerated >= ago(1h)
| where ObjectName == "Processor"
              and CounterName == "% Processor Time"
              and InstanceName!="_Total"
| sort by InstanceName asc nulls first
| summarize CPUCount = dcount(InstanceName) by Computer;
// end query

//Join all 3 datasets together
FindCPU | join(TopCPU) on Computer 
| join(TopProcess)on Computer
| extend PercentProcessorUsed = CounterValue1 / CPUCount
| summarize avg(PercentProcessorUsed) by Computer, ObjectName
                  , CounterName, CPUCount 
                  , TotalCPU=CounterValue //rename CounterValue to TotalCPU 
                  , Process=ObjectName1 //rename ObjectName1 to Process 
                  , ProcessTime=CounterName1 //rename CounterName1 to ProcessTime 
                  , ProcessName=InstanceName //rename InstanceName to ProcessName 
                  , TimeGenerated
| where Process == "Process"
and avg_PercentProcessorUsed > 25 // only return processes that are using more than 25%
| top Count by avg_PercentProcessorUsed desc
| project Computer, CPUCount
                , ProcessName , avg_PercentProcessorUsed
                , TotalCPU, Process
                , ProcessTime, TimeGenerated

Gracias

Respuesta1

La consulta se ejecuta bien (aunque parece un poco complicada para lo que intenta hacer), sin embargo, debe asegurarse de seleccionar todas las consultas cuando la ejecute.

De forma predeterminada, si el cursor está al final de todas las consultas, Log Analytics solo ejecutará la última consulta, lo que obviamente produce un error porque no puede encontrar "FindCPU". Resalta todo, luego ejecútalo y funciona bien.

información relacionada