¿Cómo restar fechas de columnas usando awk?

Question

Tengo tres columnas como esta:

18:37:12 18:37:31 0  
18:37:01 18:37:18 0

Me gustaría que la tercera columna se complete con la diferencia en segundos de las dos primeras columnas de esta manera:

18:37:12 18:37:31 19  
18:37:01 18:37:18 17

Estoy usando esto:

nova migration-list | grep completed | awk '{ print substr($22,12,8), substr($24,12,8) }' | awk 'BEGIN{ FS=" " } { print $0, $2-$1 }'

Agradezco cualquier ayuda

Answer 1

En un sistema GNU:

awk '{"date -d "$1" +%s"|getline one; "date -d "$2" +%s"|getline two; \
         print $1, $2, two-one}' file.txt

• "date -d "$1" +%s"|getline oneobtiene los segundos desde la época (usando GNU date) para el campo 1, guarda en la variableone

• "date -d "$2" +%s"|getline twohace lo mismo para el campo 2 y guarda el resultado como variabletwo

• print $1, $2, two-oneimprime el campo uno, dos y la resta de la variable dos y uno

Ejemplo:

% cat file.txt
18:37:12 18:37:31 0
18:37:01 18:37:18 0

% awk '{"date -d "$1" +%s"|getline one; "date -d "$2" +%s"|getline two; print $1, $2, two-one}' file.txt
18:37:12 18:37:31 19
18:37:01 18:37:18 17

Answer 2

Usando las funciones de tiempo integradas de GNU awk:

awk '
  function to_time(time,   t,a) {
    split(time, a, ":")
    t = mktime("1970 1 1 " a[1] " " a[2] " " a[3])
    return t
  }
  {print $1, $2, to_time($2) - to_time($1)}
' file