☰

NTP 서버 통계를 분석하는 프로그램이 있나요?

tag-icon • tag-icon 12.04 ntp
NTP 서버 통계를 분석하는 프로그램이 있나요?

저는 Ubuntu 12.04를 실행 중이고 NTP 서버가 실행 중입니다. 분명히 괜찮습니다. 저는 두 개의 Windows 7 상자에서 Meinberg NTP 서버를 실행하고 관련 서버 모니터를 사용하여 서버의 최신 상태를 추적합니다.

유사한 Linux 모니터가 있습니까? 가능하면 내 시계가 어떻게 작동하는지 등을 보여줄 수 있는 GUI가 있는 모니터가 있습니까?

답변1

귀하의 질문에 대한 정확한 답변은 아니지만 이제 /var/log/ntp/loopstats를 분석하는 gnuplot 스크립트를 사용한다고 언급하신 것으로 보입니다. 나도 똑같이 하고, 아래는 내가 직접 사용하는 것이다.

누군가 더 나은 일을 하고 있다면 나도 궁금할 것이다.

#! /usr/bin/gnuplot
# Remember to check you have these lines in /etc/ntp.conf and that ntpd is actually running:
#    statsdir /var/log/ntpstats/
#    statistics loopstats peerstats clockstats
#    filegen loopstats file loopstats type day enable
#    filegen peerstats file peerstats type day enable
#    filegen clockstats file clockstats type day enable

# Resolution: fullscreen
set term x11 size `xrandr | awk '/\*/{sub(/x/,",");print $1; exit}'`
set grid
set bars 0.4
set y2tics
set y2range [0:]
set ytics nomirror
set xdata time
set timefmt "%s"
set format x "%T"
set title "NTP statistics"
set ylabel "Clock offset / Roundtrip delay (ms)"
set y2label "Frequency offset (seconds per day)"
set xlabel "Time of day"
local_time = `date +%s --utc -d "12:00:00 $(date +%z)"`
utc_time   = `date +%s --utc -d "12:00:00"`
localdifferencefromUTC = utc_time - local_time
timeoffsettoday = `date +%s --utc -d "today 0:00"` + localdifferencefromUTC
plot \
  "/var/log/ntpstats/loopstats" u ($2+timeoffsettoday):($3*1000):($5*1000/2) t "Clock offset" w errorlines lt 1 lw 2 pt 187, \
  "/var/log/ntpstats/peerstats" u ($2+timeoffsettoday):($6*1000):($8*1000/2) t "Roundtrip delay" w errorbars lt 26 pt 26,\
  "/var/log/ntpstats/loopstats" u ($2+timeoffsettoday):($4*0.0864):($6*0.0864/2) axes x1y2 t "Frequency offset" w errorline lt 7 pt 65,\
  0 w l lt -1
pause mouse close

답변2

ntp.org는 많은 것을 제공합니다연결웹사이트의 모니터링 도구에

관련 정보