Word 문서의 모든 필드를 어떻게 업데이트하나요?

Question

업데이트 방법을 원합니다모두Word 2013 문서의 필드. (다른 버전에서도 작동한다면 더욱 좋습니다. 원래 Word 2007에서 이 문제가 있었고 그 이후로 아무것도 변경되지 않은 것 같습니다.) 여기에는 상호 참조, 페이지 번호, 목차, 색인, 머리글 등이 포함됩니다. 을 눌러 업데이트할 수 있으면 F9업데이트하고 싶습니다.

(이론적으로 필드를 업데이트하면 다른 필드도 업데이트해야 할 수 있습니다. 예를 들어 목차가 길어지면 본문의 일부 페이지 번호가 변경됩니다. 일반적인 경우를 처리하는 것만으로도 충분합니다. 실제로 실행해야 해도 괜찮습니다. 매크로가 안정화되기 전에 두세 번 반복하면 모든 것을 찾아내는 단일 매크로가 필요합니다.)

지금까지의 시도로는 그림 내부 텍스트 상자의 필드를 업데이트하지 못했습니다. 업데이트하려면 어떻게 해야 하며, 또 무엇을 놓쳤나요?

---

편집하다: 주어진 답변과 내가 이미 가지고 있는 답변을 결합하면 모든 것을 업데이트하는 것처럼 보이는 매크로가 제공됩니다(알려진 결함).

'' Update all the fields, indexes, etc. in the specified document.
Sub UpdateAllFieldsIn(doc As Document)
    '' Update tables. We do this first so that they contain all necessary
    '' entries and so extend to their final number of pages.
    Dim toc As TableOfContents
    For Each toc In doc.TablesOfContents
        toc.Update
    Next toc
    Dim tof As TableOfFigures
    For Each tof In doc.TablesOfFigures
        tof.Update
    Next tof
    '' Update fields everywhere. This includes updates of page numbers in
    '' tables (but would not add or remove entries). This also takes care of
    '' all index updates.
    Dim sr As range
    For Each sr In doc.StoryRanges
        sr.Fields.Update
        While Not (sr.NextStoryRange Is Nothing)
            Set sr = sr.NextStoryRange
            '' FIXME: for footnotes, endnotes and comments, I get a pop-up
            '' "Word cannot undo this action. Do you want to continue?"
            sr.Fields.Update
        Wend
    Next sr
End Sub
'' Update all the fields, indexes, etc. in the active document.
'' This is a parameterless subroutine so that it can be used interactively.
Sub UpdateAllFields()
    UpdateAllFieldsIn ActiveDocument
End Sub

Answer 1

인쇄 설정으로 이동하여 업데이트 필드를 선택하세요. 그런 다음 인쇄로 이동하거나 문서를 미리 봅니다.

그런데, 모든 필드가 업데이트되었습니다!

Answer 2

저는 그냥 Ctrl+ A-를 사용하여 모든 항목을 선택합니다.그 다음에 F9로트를 업데이트합니다.

그러나 머리글과 바닥글은 누락되지만 IIRC를 인쇄/인쇄 미리보기할 때 업데이트됩니다.

---

###업데이트

다음 매크로를 찾았습니다. 빠른 테스트를 통해 목차, 단락 내의 필드, 머리글 및 바닥글 내의 필드, 부동 텍스트 상자 그림 내의 필드를 업데이트했습니다.

필요한 모든 내용이 포함되었으면 좋겠습니다. 그렇지 않은 경우 여전히 업데이트에 실패하는 항목을 알려주세요.

원천:http://www.gmayor.com/installing_macro.htm

Sub UpdateAll()
    Dim oStory As Range
    For Each oStory In ActiveDocument.StoryRanges
        oStory.Fields.Update
        If oStory.StoryType <> wdMainTextStory Then
            While Not (oStory.NextStoryRange Is Nothing)
                Set oStory = oStory.NextStoryRange
                oStory.Fields.Update
            Wend
        End If
    Next oStory
    Set oStory = Nothing
End Sub

Answer 3

이것페이지재미있어 보이네요:

Word 2007을 사용하는 경우 프로세스가 약간 다릅니다. Office 버튼을 클릭한 다음 Word 옵션을 클릭합니다. Word에 Word 옵션 대화 상자가 표시됩니다. 대화 상자 왼쪽에서 고급을 클릭합니다. (관련 그림을 보려면 여기를 클릭하십시오.) 일반 영역(보려면 약간 아래로 스크롤)에서 열 때 자동 링크 업데이트 확인란이 선택되어 있는지 확인하십시오. 확인을 클릭하세요. 이 설정을 사용하면 모든 링크가 항상 최신 상태로 유지됩니다. 문서가 열릴 때 필드를 업데이트하려면 매크로를 사용하여 작업을 수행해야 합니다. 특히 문서를 열거나 닫을 때 필드를 업데이트할지 여부에 따라 AutoOpen 또는 AutoClose 매크로를 사용해야 합니다. 다음은 사용할 수 있는 AutoOpen 매크로의 예입니다.

Sub AutoOpen()
    With Options
        .UpdateFieldsAtPrint = True
        .UpdateLinksAtPrint = True
    End With
    ActiveDocument.Fields.Update
End Sub

매크로는 인쇄 시 필드와 링크를 강제로 업데이트하도록 옵션이 설정되어 있는지 확인한 다음 문서에 있는 Fields 컬렉션의 모든 구성원을 업데이트합니다. 대신 닫을 때 필드를 업데이트하려면 다음 매크로를 사용할 수 있습니다.

Sub AutoClose()
    ActiveDocument.Fields.Update
End Sub

문서를 종료할 때 인쇄 시 업데이트 옵션을 설정할 필요가 없기 때문에 이 매크로는 훨씬 더 짧습니다.

Answer 4

모든 머리글과 바닥글을 올바르게 업데이트하려면 다음이 도움이 되었습니다.

    Dim oStory As Range
    Dim oSection As Object
    Dim oHeader As Object
    Dim oFooter As Object

    For Each oStory In ActiveDocument.StoryRanges
        oStory.Fields.Update
    Next oStory

        For Each oSection In ActiveDocument.Sections
             For Each oHeader In oSection.Headers
                 oHeader.Range.Fields.Update
             Next oHeader
            
             For Each oFooter In oSection.Footers
                 oFooter.Range.Fields.Update
             Next oFooter
        Next oSection