☰

모든 PowerPoint 슬라이드의 언어를 한 번에 어떻게 변경합니까?

tag-icon • tag-icon windows microsoft-office microsoft-powerpoint microsoft-powerpoint-2010
모든 PowerPoint 슬라이드의 언어를 한 번에 어떻게 변경합니까?

Powerpoint에 있는 모든 슬라이드의 교정 언어를 변경하고 싶습니다. 언어 기본 설정 메뉴를 통해 언어 설정을 시도했지만 새 PowerPoint에서만 변경됩니다.

답변1

언어를 변경하려면전체PowerPoint를 쉽게 열고보다탭을 선택하고개요보다.

이제 누르세요

  • Ctrl+는 A모두 선택합니다.
  • 도구→언어→ 설정할 언어를 선택하세요.

마찬가지로 모든 항목을 선택한 상태에서 글꼴, 색상 등과 같은 다른 항목도 변경할 수 있습니다. 물론 대부분의 경우 슬라이드 마스터를 변경하는 것이 더 좋지만, 편집자가 많은 프레젠테이션에는 '하드' 서식 설정이 많이 있을 수 있습니다. 기본 마스터에서 벗어나 일관성을 유지하려면 재설정이 필요합니다. 개별 슬라이드를 마스터 스타일로 재설정할 수도 있지만 이로 인해 자리 표시자도 이동하게 되어 일부 상황에서는 바람직하지 않을 수 있습니다.

파워포인트 2013

  • 보다→개요Ctrl→ +를 통해 모든 슬라이드(왼쪽 메뉴)를 선택합니다 A.
  • 검토→언어→교정 언어 설정...→ 설정할 언어를 선택하세요.

나는 - 파워포인트재시작필요했습니다. 아마 나도 변했기 때문일 거야언어 편집:

  • 검토→언어→교정 언어 설정...→언어 기본 설정→편집 언어 선택.

답변2

사용파워포인트 2010개요 메뉴를 열었습니다 -

개요 탭

모든 텍스트를 선택하고(Ctrl+A) 언어 메뉴를 열고 교정 언어를 설정했습니다.

언어 옵션

그리고 그것은 효과가 있었습니다!

언어 메뉴는 검토 리본 탭(슬라이드 쇼 탭 다음, 스크린샷에는 표시되지 않음)에 있습니다.

답변3

나는 나아졌다이니고의 답변모든 항목을 원하는 언어로 변경하는 재귀 버전을 제공합니다.

이 버전은 그룹 유형인 각 모양을 재귀적으로 조사합니다. 일부 실험에 따르면 그룹 유형 msoGroup이 msoSmartArt그룹 유형입니다. 텍스트 개체를 포함할 수 있는 다른 유형의 도형을 찾으면 해당 목록에 자유롭게 추가하세요.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

답변4

Inigo, Duncan, Maria 및 DomDev의 답변을 바탕으로 현재와 미래의 모양, 테이블, 그룹, SmartArt에 적용됩니다.

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

관련 정보