☰

폴더 + 하위 폴더 생성을 위한 AHK

tag-icon • tag-icon windows-7 autohotkey
폴더 + 하위 폴더 생성을 위한 AHK

다음을 생성하는 AHK 스크립트가 필요합니다.

  • Windows 탐색기(Windows 7 아래)에서 현재 열려 있는 폴더에 있는 폴더,
  • 누구의 이름으로 구성되어 있습니까?
    • yyyy-mm-dd( ) 형식의 현재 날짜
    • 현재 클립보드에 있는 텍스트
  • 새로 생성된 폴더에는 "1", "2", "3"이라는 3개의 하위 폴더가 포함되어야 합니다.

다른 응용 프로그램에서 몇 단어(예: )를 복사하고 싶습니다. Testing Testing TestingWindows 탐색기를 사용하여 내 하드 디스크의 위치로 이동하여 단축키를 활성화하면 AHK에서 다음 이름의 폴더를 생성합니다.

2012-06-04 Testing Testing Testing

하위 폴더 "1", "2" 및 "3"이 있습니다.

답변1

스크립트

#c::
    WinGetClass, WinClass, A
    if (WinClass = "CabinetWClass")
    {
        FormatTime, CurrentDate,, yy-MM-dd
        CustomText = %Clipboard%
        Clipboard = 
        SendPlay, !d^c
        ClipWait, 1
        If ErrorLevel
        {
            MsgBox, Could not read directory name.
            return
        }
        CurrentDir = %Clipboard%
        Clipboard = %CustomText%
        NewDir = %CurrentDir%\%CurrentDate% %CustomText%
        Run, cmd /c (md "%NewDir%" || pause) && md "%NewDir%\1" && md "%NewDir%\2" && md "%NewDir%\3"
    }
    else
        SendPlay, #c
return

작동 원리

  • #c:: ... return키 조합(여기서는 Win+ C)을 지정하고 ...적중 시 실행됩니다.

  • WinGetClass, WinClass, A현재 활성 창의 제목을 변수에 저장합니다 WinClass.

  • if (WinClass = "CabinetWClass") { ... }(Windows 탐색기의 클래스) WinClass인지 확인하십시오 .CabinetWClass

    그렇다면, ...실행됩니다. 그렇지 않으면 SendPlay, #c일반 Win+ C스트로크를 에뮬레이트합니다.

  • FormatTime, CurrentDate,, yy-MM-dd현재 날짜( YY-MM-DD)를 변수에 저장합니다 CurrentDate.

  • Clipboard =클립보드를 지워서 언제 클립보드에 복사되었는지 확인할 수 있습니다.

  • CustomText = %Clipboard%현재 클립보드 내용을 변수에 복사합니다 CustomText.

  • SendPlay, !d^c주소 표시줄을 선택하고 해당 내용을 클립보드에 복사합니다.

  • ClipWait, 1클립보드에 데이터가 포함될 때까지 최대 1초 동안 기다립니다.

  • If ErrorLevel { ... }클립보드에 데이터가 포함되어 있는지 확인합니다.

    그렇지 않으면 스크립트가 중단됩니다.

  • CurrentDir = %Clipboard%현재 클립보드 내용을 변수에 복사합니다 CurrentDir.

  • Clipboard = %CustomText%클립보드를 원래 값으로 다시 설정합니다.

  • NewDir = %CurrentDir%\%CurrentDate% %CustomText%새 디렉터리의 이름을 지정합니다.

  • Run, cmd /c ...명령을 실행 ...한 후 종료됩니다.

    • (md "%NewDir%" || pause)을 만들려고 합니다 %NewDir%. 실패 시 일시정지되므로 오류 메시지를 확인할 수 있습니다.

    • md "%NewDir%\1" && md "%NewDir%\2" && md "%NewDir%\3"3개의 하위 디렉터리를 만듭니다.

관련 정보