☰

emacs는 시작한 직후에 파일을 읽을 수 없습니다

tag-icon • tag-icon windows-7 emacs
emacs는 시작한 직후에 파일을 읽을 수 없습니다

방금 Windows 7에서 emacs를 사용하기 시작했는데 매우 불안합니다. 바로 파일을 읽거나 쓸 수는 없는 것 같습니다. Cx Cf를 사용하여 시작하고 몇 초 후에 경로를 작성하려고 하면 미니버퍼가 다음과 같은 결과를 제공합니다.

wrong type argument: stringp, (\, temporary-file-directory)

하지만 몇 분 정도 기다리거나 계속 시도하면 결국 파일이 로드됩니다.

무슨 일이야?!

편집하다:

이것은 내 init.el 파일입니다. emacs는 그것 없이도 잘 실행되는 것 같습니다.

;; ***My load path***
(cd "x:/PyStuff/")
(setenv "PYTHONPATH" "c:/Python27")
(add-to-list 'load-path "c:/Users/dmvianna/.emacs.d")

;; ***server stuff***
  (require 'server)
  (when (and (= emacs-major-version 23)
         (= emacs-minor-version 1)
         (equal window-system 'w32))
    ;; Suppress error "directory ~/.emacs.d/server is unsafe" on Windows.
    (defun server-ensure-safe-dir (dir) "Noop" t))
  (condition-case nil
      (server-start)
    (error
     (let* ((server-dir (if server-use-tcp server-auth-dir server-socket-dir)))
       (when (and server-use-tcp
          (not (file-accessible-directory-p server-dir)))
     (display-warning
      'server (format "Creating %S" server-dir) :warning)
     (make-directory server-dir t)
     (server-start))))
    )

;; ***Miscellaneous inits***
(setq backup-directory-alist
'((".*" . ,temporary-file-directory)))
(setq auto-save-file-name-transforms
'((".*" ,temporary-file-directory t)))
(setq delete-by-moving-to-trash t)
(setq inhibit-startup-screen t)
(put 'upcase-region 'disabled nil)
(put 'downcase-region 'disabled nil)

;;****Python stuff****
(require 'python-mode)
(add-to-list 'auto-mode-alist '("\\.py\\'" . python-mode))
;; *Python mode fixes*
(defun python-reinstate-current-directory ()
  "When running Python, add the current directory ('') to the head of sys.path.
For reasons unexplained, run-python passes arguments to the
interpreter that explicitly remove '' from sys.path. This means
that, for example, using 'python-send-buffer' in a buffer
visiting a module's code will fail to find other modules in the
same directory.

Adding this function to 'inferior-python-mode-hook' reinstates
the current directory in Python's search path."
  (python-send-string "sys.path[0:0] = ['']"))

(add-hook 'inferior-python-mode-hook 'python-reinstate-current-directory)
;;*End Python mode fixes*


(require 'lambda-mode)
(add-hook 'python-mode-hook #'lambda-mode 1)
(require 'ipython)
(require 'anything) (require 'anything-ipython)
  (when (require 'anything-show-completion nil t)
     (use-anything-show-completion 'anything-ipython-complete
                                   '(length initial-pattern)))
 (add-hook 'python-mode-hook #'(lambda ()
                                 (define-key py-mode-map (kbd "M-<tab>") 'anything-ipython-complete)))
 (add-hook 'ipython-shell-hook #'(lambda ()
                                 (define-key py-mode-map (kbd "M-<tab>") 'anything-ipython-complete)))

(require 'comint)
  (define-key comint-mode-map (kbd "M-") 'comint-next-input)
  (define-key comint-mode-map (kbd "M-") 'comint-previous-input)
  (define-key comint-mode-map [down] 'comint-next-matching-input-from-input)
  (define-key comint-mode-map [up] 'comint-previous-matching-input-from-input)

(require 'python-pep8)
(require 'python-pylint)
(add-hook 'before-save-hook 'delete-trailing-whitespace)
(provide 'emacs-init)

답변1

이 코드 부분에서는:

(setq backup-directory-alist
'((".*" . ,temporary-file-directory)))
(setq auto-save-file-name-transforms
'((".*" ,temporary-file-directory t)))

'다음과 같이 s를 백틱으로 바꿔야 합니다 .

(setq backup-directory-alist
`((".*" . ,temporary-file-directory)))
(setq auto-save-file-name-transforms
`((".*" ,temporary-file-directory t)))

'x의미 (quote x)- x평가하지 않고 반환합니다. 백틱을 사용하면 목록 요소를 선택적으로 평가할 수 있습니다. 이 경우 이는 본질적 temporary-file-directory으로 문자 그대로 취급하지 않음을 의미합니다.

"하지만 몇 분 정도 기다리거나 계속 시도하면 결국 파일이 로드됩니다."

가장 가능성 있는 일은 결국 자동 저장을 실행하지 않고 파일을 로드하는 것입니다(따라서 손상된 backup-directory-alist및 에서 작업하지 않음으로써 오류를 방지함 auto-save-file-name-transforms). 어떤 상황에서 자동 저장이 실행되는지 잘 모르겠습니다.

관련 정보