Microsoft Access 데이터베이스 테이블 목록 생성

Question

Microsoft Access에서 데이터베이스 테이블 목록을 생성하려면 어떻게 해야 합니까?

누군가가 제안한 SQL 쿼리를 발견했습니다.꽃밥 웹사이트그러나 Access에는 아래와 같이 사용자가 구성한 쿼리를 간단히 실행할 수 있는 인터페이스가 없는 것 같습니다.

SELECT [Name]
FROM MSysObjects
WHERE Type In (1,4,6)
AND Left([Name] , 4) <> "MSys"
ORDER BY [Name]

Answer 1

쿼리에 있는 SQL을 실행할 수 있습니다. 왜냐하면 그것이 바로 그것이기 때문입니다.

1. 마법사가 아닌 쿼리 디자인에서 새 쿼리를 만듭니다.
   
2. 테이블 창을 닫습니다.
   
3. 보기를 다음으로 변경 SQL하고 문자열을 입력하세요.
4. 을 클릭합니다 RUN.
   

Answer 2

DAOin을 사용 하면 다음과 같이 할 수 있습니다 VB.

Public Sub ListTablesDAO()
    Dim db As DAO.Database
    Dim tdf As DAO.TableDef

    Set db = CurrentDb
    For Each tdf In db.TableDefs
        If (tdf.Attributes And dbSystemObject) = 0 Then
            Debug.Print tdf.Name
        End If
    Next tdf
    db.Close: Set db = Nothing
End Sub

그리고 이렇게ADO

Public Sub ListTablesADO()
    Dim rs As ADODB.Recordset

    Set rs = CurrentProject.Connection.OpenSchema(adSchemaTables)
    Do Until rs.EOF
        If rs!TABLE_TYPE = "TABLE" Then
            Debug.Print rs!TABLE_NAME
        End If
        rs.MoveNext
    Loop
    rs.Close: Set rs = Nothing
End Sub

DAO와 ADO는 데이터베이스에 대해 서로 다른 두 가지 개체 모델을 제공합니다. 어떤 버전을 선택하느냐는 선호도에 따라 다릅니다. 또한 해당 라이브러리에 대한 참조가 필요합니다.

메뉴에 다음 참조를 추가할 수 있습니다 Tools > References.