☰

다른 워크시트의 값으로 셀을 채우고 셀 주소를 3씩 증가시키는 방법은 무엇입니까?

tag-icon • tag-icon microsoft-excel worksheet-function
다른 워크시트의 값으로 셀을 채우고 셀 주소를 3씩 증가시키는 방법은 무엇입니까?

다른 워크시트의 값으로 셀을 채우는 방법을 알고 있습니다. 그런데 어떻게 세 번째 셀로 건너뛸 수 있나요?

내가하려는 일은 다음과 같습니다.

A1 ='2nd Worksheet'!C4
A2 ='2nd Worksheet'!C7
A3 ='2nd Worksheet'!C10
A4 ='2nd Worksheet'!C13
A5 ='2nd Worksheet'!C16
A6 ='2nd Worksheet'!C19
A7 ='2nd Worksheet'!C22
and so on...

'2nd Worksheet'!Cxx매번 3씩 증가 하도록 수동으로 입력할 필요가 없습니다 .

답변1

A1 셀에 다음 수식을 입력하고 아래로 드래그합니다.

=OFFSET(시트2!$C$4,3*ROW()-3,0)

답변2

다음은 몇 가지 변형입니다.

  • A1→ 셀 =OFFSET('2nd Worksheet'!C$1, 3*ROW(), 0)
    을 참조한 후 3행 × 현재 행 번호 아래로 이동합니다. 따라서 이것을 아래로 드래그/채우면 다음과 같은 결과가 나타납니다.C12nd Worksheet

    • A1→ =OFFSET('2nd Worksheet'!C$1, 3, 0)→'2nd Worksheet'!C4
    • A2→ =OFFSET('2nd Worksheet'!C$1, 6, 0)→'2nd Worksheet'!C7
    • A3→ =OFFSET('2nd Worksheet'!C$1, 9, 0)→'2nd Worksheet'!C10

    절대 행 참조로 만들려면 $in 을 지정해야 합니다 . C$1그렇지 않은 경우 아래로 드래그/채우면 다음과 같은 결과가 나타납니다.

    • A1→ =OFFSET('2nd Worksheet'!C1, 3, 0)→'2nd Worksheet'!C4
    • A2→ =OFFSET('2nd Worksheet'!C2, 6, 0)→'2nd Worksheet'!C8
    • A3→ =OFFSET('2nd Worksheet'!C3, 9, 0)→'2nd Worksheet'!C12

    (행 번호가 자동으로 증가하기 때문입니다) $C$1원한다면 말할 수 있습니다 . (열 사이를 이동하거나 복사하기 시작하지 않는 한) 아무런 차이가 없습니다.

  • A1→ =INDIRECT("'2nd Worksheet'!C" & 3*ROW()+1)
    이는 단순히 질문에 표시된 문자열을 구성한 다음 INDIRECT()해당 문자열을 역참조하는 함수를 사용합니다(즉, 문자열을 셀 주소로 처리하고 식별된 셀의 내용을 검색하기 위해).

관련 정보