정규식을 사용하려고 하는데 오류(컴파일러 오류) LIST SEPARATOR가 계속 발생합니다. 어느 부분이 잘못되었는지 알려줄 수 있는 사람이 있나요?
if instr(1,regex.Pattern([A-Z]?dtest(rt,1)),b)>0 then
답변1
InStr()은이 형식:
InStr(startCharacter, searchInText, searchForText, compareMode)
startCharacter - a number (Long)
searchInText - string (no RegEx, or pattern matching, or wildcard characters)
searchForText - string (no RegEx, or pattern matching, or wildcard characters)
compareMode - a number (from -1 to 2)
숫자(Variant - Long)를 반환합니다 searchForText
.searchInText
다음 옵션을 사용해 보세요.
Option Explicit
Sub findTxt()
Debug.Print InStrRegEx("987xyz", "[A-Z]") ' -> 4
Debug.Print getText("987xyz", "[A-Z]") ' -> x
Debug.Print InStr(1, "987xyz", "x") ' -> 4
Debug.Print InStr(1, "987xyz", getText("987xyz", "[A-Z]")) ' -> 4
Debug.Print "987xyz" Like "*[A-Za-z]" ' -> True
End Sub
Public Function InStrRegEx(ByVal searchIn As String, ByVal searchFor As String) As Long
Dim regEx As Object, found As Object
If Len(searchIn) > 0 And Len(searchFor) > 0 Then
Set regEx = CreateObject("VBScript.RegExp")
regEx.Pattern = searchFor
regEx.Global = True
regEx.IgnoreCase = True
Set found = regEx.Execute(searchIn)
If found.Count <> 0 Then InStrRegEx = found(0).FirstIndex + 1
End If
End Function
Public Function getText(ByVal searchIn As String, ByVal searchFor As String) As String
Dim regEx As Object, found As Object
If Len(searchIn) > 0 And Len(searchFor) > 0 Then
Set regEx = CreateObject("VBScript.RegExp")
regEx.Pattern = searchFor
regEx.Global = True
regEx.IgnoreCase = True
Set found = regEx.Execute(searchIn)
If found.Count <> 0 Then getText = CStr(found(0))
End If
End Function