☰

Win 10에서 하나의 드라이브 제거

tag-icon • tag-icon windows-10 onedrive
Win 10에서 하나의 드라이브 제거

저는 Amazon Cloud를 사용하고 있으며 컴퓨터에서 One Drive를 활성화하고 싶지 않습니다. 그리고 청결함의 관점에서 아이콘 등도 제거하고 싶습니다. 그러나 (놀랍지도 않게) MSFT가 이 작업을 쉽게 만든 것 같지는 않습니다. 이 작업을 수행하는 방법을 아는 사람이 있습니까? 어쩌면 레지스트리?

답변1

나는 찾았다독일 웹사이트의 스크립트. 이 텍스트를 txt 파일에 복사하고 이름을 RemoveOneDrive.cmd로 바꾸고 이 cmd를 관리자로 실행합니다.

@echo off
cls

set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"

echo OneDrive Prozess beenden
echo.
taskkill /f /im OneDrive.exe > NUL 2>&1
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive deinstallieren
echo.
if exist %x64% (
%x64% /uninstall
) else (
%x86% /uninstall
)
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive Überreste entfernen
echo.
rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1 

echo OneDrive im Datei Explorer entfernen
echo.
REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1

pause

그러면 OneDrive 프로세스가 먼저 종료되고 제거되며 Windows 탐색기에서 항목이 제거됩니다.

관련 정보