두 개의 별도 값(둘 중 하나)을 살펴보는 것을 기반으로 하는 Excel 수식 반환 값

Question

이 공식을 사용하여 아래 표의 값을 반환합니다.

=IF(ISNA(VLOOKUP(A2,USUB,1,FALSE)),"No Fruit Found",VLOOKUP(A2,USUB,2,FALSE))

USUB 테이블에는 다음 데이터가 있습니다.

Fruit          Fruit Code   FruitID Location          CITY
Apple             APP          A    SEATTLE,WA          SEATTLE
Bananas           BAN          B    MODESTO,CA          MODESTO
Cherry            CHER         C    CHARLESTON,SC       CHARLESTON
Blackberrires     BLCKB        D    VICKSBURG,VA        VICKSBURG
Blueberries       BLUB         E    SAN DIEGO,CA        SAN DIEGO
Cantaloupe        CANT         F    GULF SHORES, AL     GULF SHORES
Grapes            GRP          G    NAPA VALLEY,CA      NAPA VALLEY
Peach             PCH          H    ATLANTA, GA         ATLANTA
Grapefruit        GRPFRT       I    FT LAUDERDALE, FL   FT LAUDERDALE
Pomegranate       POM          J    HONOLULU, HI        HONOLULU
Kiwi              KIW          K    SALEM, OR           SALEM

---

먼저 과일(USUB,1)을 확인한 다음 위치(USUB,4)를 확인하고 수식의 기준에 따라 과일 코드(USUB,2) 값을 반환하려면 어떤 수식을 사용해야 합니까?

Answer 1

나는 거의 사용을 제안하지 않습니다DGET기능이지만 이는 언제 유용하게 사용할 수 있는지 보여주는 완벽한 예입니다. 설정 및 사용방법은 아래 이미지를 참고하세요

공식은 다음과 같습니다

=DGET(USUB,"Fruit Code",$A$1:$B$2)

위치를 입력하지 않으면 해당 과일에 대한 코드만 찾을 수 있다는 추가 이점도 있습니다.

일치하는 과일 및 위치 조합이 없는 경우를 잡으려면 아래를 참조하세요.

=IFERROR(DGET(USUB,"Fruit Code",$A$1:$B$2),"Not found")

Answer 2

배열로 입력된 여러 기준이 있는 색인/일치( CTRL+SHIFT+ENTER:

=INDEX($C$2:$C$13,MATCH(H3&I3,$B$2:$B$13&$E$2:$E$13,0))

(필요에 따라 조정)

그래서 과일 코드와 위치를 사용하여 ID를 반환할 수 있었습니다. 수식은 로 올바르게 해석됩니다 J. 그게 당신이 원하던 거였나요? 기본적으로 Match()기준을 와 연결 &한 다음 와 일치시킬 범위를 연결 &하고 배열로 입력하면 됩니다.

Answer 3

중복된 항목이 있는지 먼저 확인하고, 그렇지 않은 경우 위치에 입력된 내용에 관계없이 올바른 ID를 반환합니다.

해당 과일이 두 개 이상 있으면 일치하는 과일을 찾기 위해 위치를 찾습니다.

두 경우 모두 일치하는 항목을 찾을 수 없는 경우; 과일이 존재하지 않거나, 과일이 2개 이상 있을 경우 과일과 위치의 조합이 올바르지 않습니다.

=IF(COUNTIF(A:A,H2)>1,IFERROR(INDEX($C$2:$C$13,MATCH(1,INDEX(($D$2:$D$13=I2)*($A$2:$A$13=H2),),0)),"Multiple fruits but Location is wrong"),IFERROR(INDEX(C:C,MATCH(H2,A:A,0)),"Not Found"))

테이블을 참조하려면 다음을 사용하십시오.

=IF(COUNTIF(USUB[Fruit],H2)>1,IFERROR(INDEX(USUB[FruitID],MATCH(1,INDEX((USUB[Location]=I2)*(USUB[Fruit]=H2),),0)),"Multiple fruits but Location is wrong"),IFERROR(INDEX(USUB[FruitID],MATCH(H2,USUB[Fruit],0)),"Not Found"))