중복에 대한 Excel 수식

Question

누군가 C 열에 있는 정확한 데이터를 생성하는 데 필요한 수식을 친절하게 보여줄 수 있습니까?

B열의 중복 셀은 A열의 SKU를 C열로 복사합니다.

내가 이것을 설명했기를 바랍니다.

Answer 1

Office 365 Excel이 없으면 UDF가 필요합니다. 통합 문서에 첨부된 모듈에 이 코드를 넣습니다.

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    If TEXTJOIN <> "" Then 
        TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim)) 
    Else
        TEXTJOIN = ""
    End IF
End Function

그러면 다음 배열 수식이 원하는 작업을 수행합니다.

=TEXTJOIN(" | ",TRUE,IF($A$2:$A$11<>A2,IF($B$2:$B$11=B2,$A$2:$A$11,""),""))

배열 수식이므로 편집 모드를 종료할 때 Enter 대신 Ctrl-Shift-Enter를 사용하여 확인해야 합니다. 올바르게 수행되면 Excel에서 {}수식을 입력합니다.

---

Office 365 Excel이 있는 경우 위 수식을 배열 수식으로 사용하면 됩니다. UDF는 필요하지 않습니다.

UDF는 TEXTJOIN의 기능을 모방합니다.