☰

단일 인덱스 + 일치가 작동하지만 if 문에서는

tag-icon • tag-icon microsoft-excel worksheet-function microsoft-excel-2013
단일 인덱스 + 일치가 작동하지만 if 문에서는 
=IF(
A4=INDEX(Sheet1!$B:$B, MATCH(A4, Sheet1!$C:$C, 0)), 
INDEX(Sheet1!$B:$B, MATCH(A4, Sheet1!$C:$C,0)),

    IF(A4=INDEX(Source1!$A:$A, MATCH(A4, Source1!$B:$B, 0)), 
    INDEX(Source1!$A:$A, MATCH(A4, Source1!$B:$B, 0)),

        IF(A4=INDEX(Source2!$A:$A, MATCH(A4, Source2!$B:$B, 0)), 
        INDEX(Source2!$A:$A, MATCH(A4, Source2!$B:$B, 0)),

            IF(A4=INDEX(Source3!$A:$A, MATCH(A4, Source3!$B:$B, 0)), 
            INDEX(Source3!$A:$A, MATCH(A4, Source3!$B:$B, 0)))
)))

여러분, 안녕하세요! 여기에는 4개의 서로 다른 스프레드시트가 있으며 올바른 값을 반환하는 4개의 소스 스프레드시트를 모두 찾기 위해 셀 A4에서 값을 검색하려고 합니다.

이것을 시도하면 금처럼 잘 작동합니다.

INDEX(Sheet1!$B:$B, MATCH(A4, Sheet1!$C:$C,0))

그러나 이는 아래와 같은 간단한 if 문과 중첩된 if 문에서는 작동하지 않습니다. 그리고 내가 어디서 잘못했는지 전혀 모릅니다.

=IF(INDEX(Sheet1!$B:$B, MATCH(A4, Sheet1!$C:$C, 0))=A4,
    INDEX(Sheet1!$B:$B, MATCH(A4, Sheet1!$C:$C, 0)),
    "NO")

이를 통해 모든 셀은 거짓 값인 "NO"를 반환합니다. 한번 보시고 제가 뭘 잘못했는지 알려 주실 수 있나요? 귀하의 관심과 시간에 감사드립니다.

답변1

A4를 찾을 수 없으면 오류가 반환되며 자체 오류를 생성하지 않고는 오류와 동일시할 수 없습니다.

대신 이것을 사용하십시오:

=IF(
ISNUMBER(MATCH(A4, Sheet1!$C:$C, 0)), 
INDEX(Sheet1!$B:$B, MATCH(A4, Sheet1!$C:$C,0)),

    IF(ISNUMBER(MATCH(A4, Source1!$B:$B, 0)), 
    INDEX(Source1!$A:$A, MATCH(A4, Source1!$B:$B, 0)),

        IF(ISNUMBER(MATCH(A4, Source2!$B:$B, 0)), 
        INDEX(Source2!$A:$A, MATCH(A4, Source2!$B:$B, 0)),

            IF(ISNUMBER(MATCH(A4, Source3!$B:$B, 0)), 
            INDEX(Source3!$A:$A, MATCH(A4, Source3!$B:$B, 0)))
)))

관련 정보