Excel 2010 VBA - 매크로의 시작점을 이동하시겠습니까?

Question

안녕하세요 여러분(첫 번째 게시물입니다. ㅋㅋㅋ), 저는 매크로가 다른 셀의 Sheet1에서 시작되도록 하는 방법을 알 수 없다는 점을 제외하고는 수행하는 데 필요한 작업을 정확히 수행하는 매크로를 받았습니다. 현재 B3 셀에 필요한 정보를 게시하고 있지만 B10 셀에서 시작하고 싶습니다. 생각?

Sub Button1_Click()

    Sheets("Sheet1").Range("B2:B600").ClearContents

    For i = 1 To 30
generate:

        RowNum = Application.RoundUp(Rnd() * 88, 0)

        If Application.CountIf(Sheets("Sheet1").[B:B], _
        Sheets("Sheet2").Cells(RowNum, "A")) = 0 Then

            Sheets("Sheet1").Range("B" & Rows.Count).End(xlUp).Offset(2).Value = _
            Sheets("Sheet2").Cells(RowNum, "A").Value
        Else
            GoTo generate
        End If
    Next i

End Sub

Answer 1

이것을 사용하십시오

---

Option Explicit

Public Sub Button1_Click()
    Const RNG = "B2:B600"   '<--- Range on Sheet1 --------------------
    Const OFFSET_ROW = 2
    Const START_ROW = 10    '<--- Start row --------------------------

    Dim ws1 As Worksheet:   Set ws1 = ThisWorkbook.Worksheets("Sheet1")
    Dim ws2 As Worksheet:   Set ws2 = ThisWorkbook.Worksheets("Sheet2")

    Dim r As Long, ws2val As String

    ws1.Range(RNG).ClearContents

    For r = START_ROW To 30 * OFFSET_ROW + START_ROW - 1 Step OFFSET_ROW

        ws2val = ws2.Cells(Application.RoundUp(Rnd() * 88, 0), "A").Value

        If Application.CountIf(ws1.Range(RNG), ws2val) = 0 Then
            ws1.Range("B" & r).Value = ws2val
        Else
            r = r - OFFSET_ROW
        End If
    Next
End Sub

---

테스트 데이터시트2및 결과시트1
(의도한 대로 10행부터 출력이 시작됩니다.)