☰

인쇄 후 4개의 서로 다른 셀에서 일련 번호 증가

tag-icon • tag-icon microsoft-excel worksheet-function vba printing
인쇄 후 4개의 서로 다른 셀에서 일련 번호 증가

1/4 Letter 크기의 영수증을 만들어 하나의 워크시트에 4번 복사했습니다(서류 절약을 위해). 001부터 100까지 연속으로 인쇄되기를 원합니다. 각 영수증에는 고유한 일련번호 001,002...100이 있어야 합니다.

A1, C1, E1 및 G1이 숫자 001,002,003,004를 가진 셀이라고 가정하고 4개의 서로 다른 셀에 일련 번호를 입력하고 인쇄할 때마다 각 숫자를 늘리려면 어떻게 해야 합니까?

또한 시작 번호를 지정하는 기능도 필요합니다.

웹에서 이것을 찾았으므로 시작이 될 수 있습니다.

Sub IncrementPrint()

    Dim xCount As Variant
    Dim xScreen As Boolean
    Dim I As Long
    On Error Resume Next
LInput:
    xCount = Application.InputBox("Please enter the number of copies you want to print:", "Title")
    If TypeName(xCount) = "Boolean" Then Exit Sub
    If (xCount = "") Or (Not IsNumeric(xCount)) Or (xCount < 1) Then
        MsgBox "error entered, please enter again", vbInformation, "Title"
        GoTo LInput
    Else
        xScreen = Application.ScreenUpdating
        Application.ScreenUpdating = False
        For I = 1 To xCount
            ActiveSheet.Range("A1").Value = " Company-00" & I
            ActiveSheet.PrintOut
        Next
        ActiveSheet.Range("A1").ClearContents
        Application.ScreenUpdating = xScreen
    End If
End Sub

답변1

이것을 사용하십시오

Option Explicit

Public Sub IncrementPrint()
    Dim resp As Variant, scr As Boolean, i As Long, j As Long

On Error Resume Next
    resp = Application.InputBox(Prompt:="Please enter the number of copies to print:", _
                                Title:="Select Total Print Copies", Type:=1)
On Error GoTo 0

    If resp = False Then Exit Sub
    If resp < 1 Or resp > 100 Then
        MsgBox "Invalid number: " & resp & " (Enter 1 to 100)", vbExclamation, "Try Again"
        Exit Sub
    End If

    scr = Application.ScreenUpdating
    Application.ScreenUpdating = False
    j = 0
    For i = 1 To resp
        ActiveSheet.Range("A1").Value2 = " Company-00" & i + 0 + j
        ActiveSheet.Range("C1").Value2 = " Company-00" & i + 1 + j
        ActiveSheet.Range("E1").Value2 = " Company-00" & i + 2 + j
        ActiveSheet.Range("G1").Value2 = " Company-00" & i + 3 + j
        ActiveSheet.PrintOut
        j = j + 3
    Next i
    ActiveSheet.Range("A1,C1,E1,G1").ClearContents
    Application.ScreenUpdating = scr
End Sub

관련 정보