☰

이미지 파일 세트의 이름을 대량으로 변경

tag-icon • tag-icon windows batch-rename
이미지 파일 세트의 이름을 대량으로 변경

우리는 여기에 설명된 6개의 카메라로 구성된 곤충 이미징 설정을 사용합니다.https://osf.io/s2p73/

작업 흐름의 일부에는 데이터베이스로 가져올 수 있도록 이미지 파일의 이름을 바꾸는 작업이 포함됩니다. 현재 대량 이름 바꾸기 유틸리티의 여러 "쌍 이름 바꾸기" 단계를 통해 이 작업을 수행하고 있으며 프로세스를 단순화할 단일 DOS 배치 파일을 찾고 있습니다. 이미지는 아래와 같이 초기 이름->최종 이름을 가진 두 개의 폴더에서 시작하고 유지됩니다. 매일 폴더 1에는 최대 1000개의 이미지가 있고 폴더 2에는 해당 5000개의 이미지가 처리됩니다.

첫 번째 숫자는 표본(0001/2/3/4/5 등)을 나타냅니다. 아래의 굵은 숫자는 이름을 바꾸는 동안 다른 5개의 이미지로 전송되어야 하는 고유한 카탈로그 번호이며, 카탈로그 번호 뒤의 마지막 두 숫자는 이미지 세트마다 다를 수 있습니다.

폴더 1: "이름이 변경됨"

0001_ALICE1-012345678_887856_162658.jpg --> 012345678_887856_162658.jpg

폴더 2: "추가"

0001_ALICE2.jpg -->012345678_측면.jpg

0001_ALICE3.jpg -->012345678_추가_1.jpg

0001_ALICE4.jpg -->012345678_추가_2.jpg

0001_ALICE5.jpg -->012345678_추가_3.jpg

0001_ALICE6.jpg -->012345678_추가_4.jpg

다음 이미지 세트는 0002_etc이고 다른 이미지 세트를 갖습니다.목록 숫자양도됩니다. 어떤 도움이라도 주시면 감사하겠습니다!

답변1

  • 일치하는 패턴으로 Folder1의 파일을 반복합니다.
  • 기본 파일 이름( %%F) 을 여러 부분( ) 으로 분할 -합니다 ._%%A..%%E
  • %%C..%%EAlice1 파일의 이름을 바꾸는 데 사용
  • %%A귀하의 구성표에 따라 다른 이름을 바꾸는 데 사용하십시오 .

내 Ramdisk A에 있는 테스트 폴더/파일의 초기 트리:

> tree a:\ /f
A:\
├───Additional
│       0001_ALICE2.jpg
│       0001_ALICE3.jpg
│       0001_ALICE4.jpg
│       0001_ALICE5.jpg
│       0001_ALICE6.jpg
│
└───Renamed
        0001_ALICE1-012345678_887856_162658.jpg

이 배치 파일은 다음과 같습니다.

:: Q:\Test\2019\03\30\SU_1419303.cmd
@Echo off
set "Folder1=A:\Renamed"
set "Folder2=A:\Additional"

For /f "delims=" %%F in ('
    Dir /B/S/A-D "%Folder1%\????_Alice?-*_*_*.jpg
') Do For /F "tokens=1-5 delims=-_" %%A in ("%%~nF") DO (
    Echo %%~nxF
    Echo %%A %%B %%C %%D %%E
    Ren "%%~fF" "%%C_%%D_%%E%%~xF"

    Ren "%Folder2%\%%A_ALICE2.jpg"  "%%C_lateral.jpg"     
    Ren "%Folder2%\%%A_ALICE3.jpg"  "%%C_additional_1.jpg"
    Ren "%Folder2%\%%A_ALICE4.jpg"  "%%C_additional_2.jpg"
    Ren "%Folder2%\%%A_ALICE5.jpg"  "%%C_additional_3.jpg"
    Ren "%Folder2%\%%A_ALICE6.jpg"  "%%C_additional_4.jpg"
)

다음 결과가 나옵니다.

> Q:\Test\2019\03\30\SU_1419303.cmd
0001_ALICE1-012345678_887856_162658.jpg
0001 ALICE1 012345678 887856 162658

> tree a:\ /f
A:\
├───Additional
│       012345678_additional_1.jpg
│       012345678_additional_2.jpg
│       012345678_additional_3.jpg
│       012345678_additional_4.jpg
│       012345678_lateral.jpg
│
└───Renamed
        012345678_887856_162658.jpg

관련 정보