단일 셀 수식에 두 개 이상의 IF ISNUMBER SEARCH 함수를 중첩하는 방법은 무엇입니까?

Question

한 셀에 두 개 이상의 ( ISNUMBER SEARCH) 문을 중첩하려고 하는데 마지막 두 개는 작동하지 않습니다. 처음 두 인수("n/a" 및 "r")는 작동하지만 세 번째와 네 번째 인수는 잘못된 데이터를 가져옵니다.

한 셀에 두 개 이상의 검색이 가능합니까? 내 공식이 어디에서 잘못되었나요?

=IF(ISNUMBER(SEARCH("N/A",$L2)),$E2+$AY$2,IF(ISNUMBER(SEARCH("r",$L2)),$E2+$AY$3,IF(ISNUMBER(SEARCH("rr",$L2)),$E2+$AY$4,IF(ISNUMBER(SEARCH("rrr",$L2)),$E2+$AY$5))))

미리 도움을 주셔서 감사합니다.

Answer 1

이는 수식이 "rr" 및 "rrr" 셀 값에서 단일 "r"을 찾기 때문에 발생합니다. ISNUMBER 조건의 순서를 변경해 보세요. "rrr"로 시작한 다음 "rr", 마지막으로 "r"로 시작합니다. 작동해야합니다.

=IF(ISNUMBER(SEARCH("N/A",$L2)),$E2+$AY$2,IF(ISNUMBER(SEARCH("rrr",$L2)),$E2+$AY$5,IF(ISNUMBER(SEARCH("rr",$L2)),$E2+$AY$4,IF(ISNUMBER(SEARCH("r",$L2)),$E2+$AY$3))))

안부 인사, 루카스

Answer 2

우리가 보는 공식을 예측하면 다음과 같습니다.

IF( ISNUMBER(SEARCH("N/A",$L2)),
    $E2+$AY$2,
    IF( ISNUMBER(SEARCH("r",$L2)),
        $E2+$AY$3,
        IF( ISNUMBER(SEARCH("rr",$L2)),
            $E2+$AY$4,
            IF( ISNUMBER(SEARCH("rrr",$L2)),
                $E2+$AY$5
              )
          )
      )
  )

이제 우리는 다음을 봅니다:

1. 마지막(가장 내부) IF()에는 ELSE 섹션이 포함되어 있지 않습니다.
2. 두 번째 IF()는 내부 IF()에 의해 테스트된 모든 값에 대해 True를 제공합니다. 따라서 외부 IF()가 이미 이 작업을 수행했기 때문에 내부 IF()는 True를 제공할 수 없습니다.

권장사항: SEARCH()를 간단한 방정식 테스트로 대체하세요.

Answer 3

이 기능을 SEARCH사용하면 ISNUMBER셀에 특정 텍스트가 포함되어 있는지 확인하는 데 사용할 수 있습니다.

SEARCH발견된 경우 검색 문자열의 위치를 ​​반환하고 수식은 ISNUMBER숫자 위치를 찾기 위해 를 사용하여 검색 문자열이 발견되었는지 여부를 테스트합니다.

귀하의 경우 rr또는 을 찾는 동안 수식은 사이 및 안을 rrr찾고 매번 또는 대신 계산합니다 .rrrrrr$E2+$AY$3$E2+$AY$4$E2+$AY$5

L2다른 텍스트가 포함되어 있거나 동일한 수식이 작동합니다 rr.rrr

@Muji가 트릭을 수행하고 검색 문자열을 역순으로 사용하여 수식이 첫 번째를 찾아서 rrr제대로 rr작동 하도록 했습니다 r.rrr

단순한 사람은 IF function이 모든 것을 성공적으로 테스트할 수 있습니다.

=IF($L$2="N/A",$E$2+$AY$2,IF($L$2="r",$E$2+$AY$3,IF($L$2="rr",$E$2+$AY$4,IF($L$2="rrr",$E$2+$AY$5))))

필요에 따라 수식의 셀 참조를 조정합니다.