Excel SUMIF - OFFSET 조건이 충족되면 같은 행에 있는 두 개의 OFFSET 셀을 합산합니다.

Question

다음과 같은 테이블이 있습니다.

TABLE A

NAME     VALUE 1   VALUE 2   RESULT
Daniel   1         4
John     3         5
Daniel   5         8

위의 셀을 확인하는 RESULT 열 내에서 SUMIF를 실행해야 하며(OFFSET 사용) 조건이 충족되면 두 가지(OFFSET) VALUES를 모두 추가하고 싶습니다. 두 개의 SUMIF를 수행하면 이를 달성할 수 있다는 것을 알고 있지만 하나만 사용하여 코드를 더 읽기 쉽고 빠르게 만드는 것이 가능한지 알고 싶습니다. 나는 행운을 빌어 다음을 시도했습니다.

SUMIF(OFFSET($A$2,0,0,ROW()-ROW($A$2),1), "Daniel", SUM(OFFSET($B$2,0,0,ROW()-ROW($B$2),1),OFFSET($C$2,0,0,ROW()-ROW($C$2),1)))

그리고:

IF(OFFSET($A$2,0,0,ROW()-ROW($A$2),1)="Daniel", SUM(OFFSET($B$2,0,0,ROW()-ROW($B$2),1),OFFSET($C$2,0,0,ROW()-ROW($C$2),1),0)

결과는 다음과 같습니다.

TABLE A

NAME     VALUE 1   VALUE 2   RESULT
Daniel   1         4         0
John     3         5         5
Daniel   5         8         5
John     1         5         18

Answer 1

구조화된 테이블 참조를 사용하지 않는 경우 오프셋이 필요하지 않습니다.

=SUMIF($A$1:A1,"Daniel",$B$1:B1)+SUMIF($A$1:A1,"Daniel",$C$1:C1)

하나의 수식을 원하면 배열 수식이 됩니다.

 =SUM(IF($A$1:A1="Daniel",$B$1:B1+$C$1:C1,0))

버전에 따라 편집 모드를 종료할 때 Enter 대신 Ctrl-Shift-Enter를 사용해야 할 수도 있습니다.

---

실제 테이블에 대한 구조적 참조를 사용하는 경우 예 오프셋이 필요합니다.

=SUM(IF(OFFSET(Table2[[#Headers],[NAME]],,,ROW($ZZ1))="Daniel",OFFSET(Table2[[#Headers],[VALUE 1]],,,ROW($ZZ1))+OFFSET(Table2[[#Headers],[VALUE 2]],,,ROW($ZZ1)),0))

다시 말하지만, 버전에 따라 편집 모드를 종료할 때 Enter 대신 Ctrl-Shift-Enter를 사용해야 할 수도 있습니다.